Version bump.

(Portage version: 2.2.0_alpha102/cvs/Linux x86_64)

2 files changed, 67 insertions, 2 deletions

diff --git a/net-misc/gsutil/ChangeLog b/net-misc/gsutil/ChangeLog
index 8dda219c067f..541786c87213 100644
--- a/net-misc/gsutil/ChangeLog
+++ b/net-misc/gsutil/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/gsutil
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/gsutil/ChangeLog,v 1.4 2011/12/13 19:55:27 vapier Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/gsutil/ChangeLog,v 1.5 2012/05/21 21:48:27 vapier Exp $
+
+*gsutil-3.7 (21 May 2012)
+
+  21 May 2012; Mike Frysinger <vapier@gentoo.org> +gsutil-3.7.ebuild:
+  Version bump.
 
 *gsutil-2011.21.11-r1 (13 Dec 2011)
 
diff --git a/net-misc/gsutil/gsutil-3.7.ebuild b/net-misc/gsutil/gsutil-3.7.ebuild
new file mode 100644
index 000000000000..9730b19948c9
--- /dev/null
+++ b/net-misc/gsutil/gsutil-3.7.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/gsutil/gsutil-3.7.ebuild,v 1.1 2012/05/21 21:48:27 vapier Exp $
+
+EAPI="3"
+
+inherit eutils python multilib
+
+DESCRIPTION="command line tool for interacting with cloud storage services"
+HOMEPAGE="http://code.google.com/p/gsutil/"
+SRC_URI="http://commondatastorage.googleapis.com/pub/${PN}_${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+DEPEND=""
+RDEPEND="${DEPEND}
+	>=dev-python/boto-2.4.0"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	# use system boto
+	rm -rf boto
+	epatch "${FILESDIR}"/${PN}-system-boto.patch
+
+	# use the custom internal path to avoid polluting python system
+	sed -i \
+		-e "/^gsutil_bin_dir =/s:=.*:= '/usr/$(get_libdir)/${PN}';sys.path.insert(0, gsutil_bin_dir);:" \
+		gsutil || die
+
+	# trim some cruft
+	find gslib third_party -name README -delete
+}
+
+src_install() {
+	dobin gsutil || die
+
+	insinto /usr/$(get_libdir)/${PN}
+	doins -r gslib oauth2_plugin third_party VERSION || die
+
+	# http://code.google.com/p/gsutil/issues/detail?id=96
+	rm "${D}"/usr/$(get_libdir)/${PN}/gslib/commands/test.py || die
+
+	dodoc README
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r cloud{auth,reader}
+	fi
+}
+
+pkg_postinst() {
+	python_mod_optimize /usr/$(get_libdir)/${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/$(get_libdir)/${PN}
+}