Bump to 3.0.2, from gnome overlay for GNOME 3

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

3 files changed, 140 insertions, 15 deletions

diff --git a/net-im/empathy/ChangeLog b/net-im/empathy/ChangeLog
index 816a84b58ac6..8d88749ecf55 100644
--- a/net-im/empathy/ChangeLog
+++ b/net-im/empathy/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/empathy
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/ChangeLog,v 1.89 2011/08/06 11:35:50 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/ChangeLog,v 1.90 2011/08/18 06:22:13 nirbheek Exp $
+
+*empathy-3.0.2 (18 Aug 2011)
+
+  18 Aug 2011; Nirbheek Chauhan <nirbheek@gentoo.org> +empathy-3.0.2.ebuild,
+  metadata.xml:
+  Bump to 3.0.2, from gnome overlay for GNOME 3
 
   06 Aug 2011; Zac Medico <zmedico@gentoo.org> empathy-2.34.0-r1.ebuild:
   Add ~x86-linux keyword.
diff --git a/net-im/empathy/empathy-3.0.2.ebuild b/net-im/empathy/empathy-3.0.2.ebuild
new file mode 100644
index 000000000000..b6b9f86f100f
--- /dev/null
+++ b/net-im/empathy/empathy-3.0.2.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-im/empathy/empathy-3.0.2.ebuild,v 1.1 2011/08/18 06:22:13 nirbheek Exp $
+
+EAPI="3"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_DEPEND="2:2.4"
+
+inherit eutils gnome2 multilib python
+
+DESCRIPTION="Telepathy client and library using GTK+"
+HOMEPAGE="http://live.gnome.org/Empathy"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux"
+# FIXME: Add location support once geoclue stops being idiotic with automagic deps
+IUSE="debug eds +gnome +map +geoloc +networkmanager sendto spell test webkit"
+
+# FIXME: gst-plugins-bad is required for the valve plugin. This should move to good
+# eventually at which point the dep can be dropped
+RDEPEND=">=dev-libs/glib-2.27.2:2
+	>=x11-libs/gtk+-3.0.2:3
+	>=dev-libs/dbus-glib-0.51
+	>=net-libs/telepathy-glib-0.14.1
+	>=media-libs/libcanberra-0.25[gtk3]
+	>=x11-libs/libnotify-0.7
+	>=gnome-base/gnome-keyring-2.91.4-r300
+	>=net-libs/gnutls-2.8.5
+	>=dev-libs/folks-0.4
+
+	gnome-base/gsettings-desktop-schemas
+	net-libs/farsight2
+	media-libs/gstreamer:0.10
+	media-libs/gst-plugins-base:0.10
+	media-libs/gst-plugins-bad
+	>=net-libs/telepathy-farsight-0.0.14
+	dev-libs/libxml2:2
+	x11-libs/libX11
+	net-voip/telepathy-connection-managers
+	>=net-im/telepathy-logger-0.2.8
+
+	eds? ( >=gnome-extra/evolution-data-server-1.2 )
+	geoloc? ( >=app-misc/geoclue-0.11 )
+	gnome? ( >=gnome-base/gnome-control-center-3.0.0 )
+	map? (
+		media-libs/libchamplain:0.10[gtk]
+		media-libs/clutter-gtk:1.0 )
+	networkmanager? ( >=net-misc/networkmanager-0.7 )
+	sendto? ( >=gnome-extra/nautilus-sendto-2.90.0 )
+	spell? (
+		>=app-text/enchant-1.2
+		>=app-text/iso-codes-0.35 )
+	webkit? ( >=net-libs/webkit-gtk-1.3.2:3 )
+"
+# Will not build with gnome-control-center-3.1.4 due to removed headers,
+# but should (probably) continue to run
+DEPEND="${RDEPEND}
+	app-text/scrollkeeper
+	>=app-text/gnome-doc-utils-0.17.3
+	>=dev-util/intltool-0.35.0
+	>=dev-util/pkgconfig-0.16
+	gnome? ( <gnome-base/gnome-control-center-3.1.4 )
+	test? (
+		sys-apps/grep
+		>=dev-libs/check-0.9.4 )
+	dev-libs/libxslt
+"
+PDEPEND=">=net-im/telepathy-mission-control-5.7.6"
+
+pkg_setup() {
+	DOCS="CONTRIBUTORS AUTHORS ChangeLog NEWS README"
+
+	# TODO: Re-add location support
+	G2CONF="${G2CONF}
+		--disable-coding-style-checks
+		--disable-schemas-compile
+		--disable-static
+		--disable-meego
+		--disable-Werror
+		$(use_enable debug)
+		$(use_with eds)
+		$(use_enable geoloc location)
+		$(use_enable gnome control-center-embedding)
+		$(use_enable map)
+		$(use_with networkmanager connectivity nm)
+		$(use_enable sendto nautilus-sendto)
+		$(use_enable spell)
+		$(use_enable webkit)"
+
+	# Build time python tools needs python2
+	python_set_active_version 2
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	python_convert_shebangs -r 2 tools
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	emake check || die "emake check failed."
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	elog "Empathy needs telepathy's connection managers to use any IM protocol."
+	elog "See the USE flags on net-voip/telepathy-connection-managers"
+	elog "to install them."
+}
diff --git a/net-im/empathy/metadata.xml b/net-im/empathy/metadata.xml
index d79757bb6c01..8ea9ff10b13d 100644
--- a/net-im/empathy/metadata.xml
+++ b/net-im/empathy/metadata.xml
@@ -1,18 +1,25 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>net-im</herd>
-<herd>gnome</herd>
-<use>
-  <flag name="map">Enable world map support through <pkg>media-libs/libchamplain</pkg>.</flag>
-  <flag name="nautilus">Enable nautilus-sendto support</flag>
-  <flag name="webkit">Build support for Adium-style HTML-based conversation
-	  window themes using <pkg>net-libs/webkit-gtk</pkg></flag>
-</use>
-  <longdescription>Empathy consists of a rich set of reusable instant messaging
-  widgets, and a GNOME client using those widgets. It uses Telepathy and Nokia's
-  Mission Control, and reuses Gossip's UI. The main goal is to permit desktop
-  integration by providing libempathy and libempathy-gtk libraries.
-  libempathy-gtk is a set of powerful widgets that can be embeded into any GNOME
-  application. A client application is provided.</longdescription>
+	<herd>net-im</herd>
+	<herd>gnome</herd>
+	<use>
+		<flag name="geoloc">Enable geolocation support through
+			<pkg>app-misc/geoclue</pkg></flag>
+		<flag name="map">Enable world map support through
+			<pkg>media-libs/libchamplain</pkg></flag>
+		<flag name="nautilus">Enable nautilus-sendto support</flag>
+		<flag name="sendto">Enable support for sending files to various devices
+			using <pkg>gnome-extra/nautilus-sendto</pkg></flag>
+		<flag name="webkit">Build support for Adium-style HTML-based conversation
+	  		window themes using <pkg>net-libs/webkit-gtk</pkg></flag>
+	</use>
+	<longdescription>
+		Empathy consists of a rich set of reusable instant messaging widgets,
+		and a GNOME client using those widgets. It uses Telepathy and Nokia's
+		Mission Control. The main goal is to permit desktop integration by 
+		providing libempathy and libempathy-gtk libraries. libempathy-gtk is a
+		set of powerful widgets that can be embeded into any GNOME application.
+		A client application is provided.
+	</longdescription>
 </pkgmetadata>