Version bump.

(Portage version: 2.2.0_alpha81/cvs/Linux x86_64)

2 files changed, 84 insertions, 1 deletions

diff --git a/media-video/mkvtoolnix/ChangeLog b/media-video/mkvtoolnix/ChangeLog
index 6bee4e4a870e..b6fe78c69a82 100644
--- a/media-video/mkvtoolnix/ChangeLog
+++ b/media-video/mkvtoolnix/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/mkvtoolnix
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.153 2011/11/29 20:35:26 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.154 2011/12/20 00:07:44 radhermit Exp $
+
+*mkvtoolnix-5.2.0 (20 Dec 2011)
+
+  20 Dec 2011; Tim Harder <radhermit@gentoo.org> +mkvtoolnix-5.2.0.ebuild:
+  Version bump.
 
 *mkvtoolnix-5.1.0 (29 Nov 2011)
 
diff --git a/media-video/mkvtoolnix/mkvtoolnix-5.2.0.ebuild b/media-video/mkvtoolnix/mkvtoolnix-5.2.0.ebuild
new file mode 100644
index 000000000000..57f74156337a
--- /dev/null
+++ b/media-video/mkvtoolnix/mkvtoolnix-5.2.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.2.0.ebuild,v 1.1 2011/12/20 00:07:44 radhermit Exp $
+
+EAPI=4
+
+inherit wxwidgets autotools
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
+SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="bzip2 debug lzo pch wxwidgets"
+
+RDEPEND="
+	>=dev-libs/libebml-1.2.2
+	>=media-libs/libmatroska-1.3.0
+	>=dev-libs/boost-1.46.0
+	dev-libs/expat
+	media-libs/flac
+	media-libs/libogg
+	media-libs/libvorbis
+	sys-apps/file
+	>=sys-devel/gcc-4.6
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	lzo? ( dev-libs/lzo )
+	wxwidgets? ( x11-libs/wxGTK:2.8[X] )
+"
+DEPEND="${RDEPEND}
+	dev-ruby/rake
+"
+
+src_prepare() {
+	# Disable automagic curl dep used for online update checking
+	sed -i -e '/curl/d' configure.in
+	export CURL_CFLAGS="" CURL_LIBS=""
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	use pch || myconf="${myconf} --disable-precompiled-headers"
+
+	if use wxwidgets ; then
+		WX_GTK_VER="2.8"
+		need-wxwidgets unicode
+		myconf="${myconf} --with-wx-config=${WX_CONFIG}"
+	fi
+
+	econf \
+		$(use_enable lzo) \
+		$(use_enable bzip2 bz2) \
+		$(use_enable wxwidgets) \
+		$(use_enable debug) \
+		--disable-qt \
+		${myconf} \
+		--with-boost-regex=boost_regex \
+		--with-boost-filesystem=boost_filesystem \
+		--with-boost-system=boost_system
+}
+
+src_compile() {
+	rake || die "rake failed"
+}
+
+src_install() {
+	# Don't run strip while installing stuff, leave to portage the job.
+	DESTDIR="${D}" rake install || die
+
+	dodoc AUTHORS ChangeLog README TODO
+	doman doc/man/*.1
+}