Version bump, closes #331771. Bug fixes and new format support.

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 70 insertions, 1 deletions

diff --git a/media-video/subtitleeditor/ChangeLog b/media-video/subtitleeditor/ChangeLog
index 1b5ec87149a4..5628d934658f 100644
--- a/media-video/subtitleeditor/ChangeLog
+++ b/media-video/subtitleeditor/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/subtitleeditor
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/subtitleeditor/ChangeLog,v 1.8 2010/04/21 18:04:19 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/subtitleeditor/ChangeLog,v 1.9 2010/08/12 21:58:38 eva Exp $
+
+*subtitleeditor-0.37.1 (12 Aug 2010)
+
+  12 Aug 2010; Gilles Dartiguelongue <eva@gentoo.org>
+  +subtitleeditor-0.37.1.ebuild:
+  Version bump, closes #331771. Bug fixes and new format support.
 
   21 Apr 2010; Christian Faulhammer <fauli@gentoo.org>
   subtitleeditor-0.36.1.ebuild:
diff --git a/media-video/subtitleeditor/subtitleeditor-0.37.1.ebuild b/media-video/subtitleeditor/subtitleeditor-0.37.1.ebuild
new file mode 100644
index 000000000000..4dc3225cf2f7
--- /dev/null
+++ b/media-video/subtitleeditor/subtitleeditor-0.37.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/subtitleeditor/subtitleeditor-0.37.1.ebuild,v 1.1 2010/08/12 21:58:38 eva Exp $
+
+EAPI="2"
+
+inherit eutils versionator flag-o-matic
+
+DESCRIPTION="GTK+2 subtitle editing tool."
+HOMEPAGE="http://home.gna.org/subtitleeditor/"
+SRC_URI="http://download.gna.org/${PN}/$(get_version_component_range 1-2)/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug nls opengl"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-cpp/gtkmm-2.14
+	>=dev-cpp/glibmm-2.16.3
+	>=dev-cpp/libxmlpp-2.20
+	>=app-text/enchant-1.4
+	>=dev-cpp/gstreamermm-0.10.4
+	>=media-libs/gst-plugins-good-0.10
+	>=media-plugins/gst-plugins-meta-0.10-r2:0.10
+	>=media-plugins/gst-plugins-pango-0.10
+	>=media-plugins/gst-plugins-xvideo-0.10
+	opengl? ( >=dev-cpp/gtkglextmm-1.2 )
+"
+# gst-plugins-pango needed for text overlay
+# gst-plugins-xvideo needed for video output
+
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	dev-util/pkgconfig"
+
+src_configure() {
+	export GST_REGISTRY="${T}/home/registry.cache.xml"
+
+	# Avoid using --enable-debug as it mocks with CXXFLAGS and LDFLAGS
+	use debug && append-flags -DDEBUG
+
+	econf \
+		--disable-debug \
+		$(use_enable nls) \
+		$(use_enable opengl gl)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
+
+	# plugins are loaded without the help of libtool files
+	find "${D}" -name '*.la' -delete || die "failed to remove *.la files"
+}
+
+pkg_postinst() {
+	ewarn
+	ewarn "If ${PN} doesn't play some video format, please check your"
+	ewarn "USE flags on media-plugins/gst-plugins-meta"
+	ewarn
+}