Revision bump to properly install GUI help files (bug #398041 by Chris Mayo).

(Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

2 files changed, 86 insertions, 1 deletions

diff --git a/media-video/mkvtoolnix/ChangeLog b/media-video/mkvtoolnix/ChangeLog
index 52aa007d600e..47a66dbc04d2 100644
--- a/media-video/mkvtoolnix/ChangeLog
+++ b/media-video/mkvtoolnix/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/mkvtoolnix
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.165 2012/05/29 05:20:36 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.166 2012/05/29 05:34:16 radhermit Exp $
+
+*mkvtoolnix-5.0.1-r1 (29 May 2012)
+
+  29 May 2012; Tim Harder <radhermit@gentoo.org> +mkvtoolnix-5.0.1-r1.ebuild:
+  Revision bump to properly install GUI help files (bug #398041 by Chris Mayo).
 
 *mkvtoolnix-5.6.0 (29 May 2012)
 
diff --git a/media-video/mkvtoolnix/mkvtoolnix-5.0.1-r1.ebuild b/media-video/mkvtoolnix/mkvtoolnix-5.0.1-r1.ebuild
new file mode 100644
index 000000000000..a9e4898b019d
--- /dev/null
+++ b/media-video/mkvtoolnix/mkvtoolnix-5.0.1-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.0.1-r1.ebuild,v 1.1 2012/05/29 05:34:16 radhermit Exp $
+
+EAPI=4
+
+inherit wxwidgets autotools
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
+SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="bzip2 debug lzo pch wxwidgets"
+
+RDEPEND="
+	>=dev-libs/libebml-1.2.2
+	>=media-libs/libmatroska-1.3.0
+	>=dev-libs/boost-1.36.0
+	dev-libs/expat
+	media-libs/flac
+	media-libs/libogg
+	media-libs/libvorbis
+	sys-apps/file
+	sys-libs/zlib
+	bzip2? ( app-arch/bzip2 )
+	lzo? ( dev-libs/lzo )
+	wxwidgets? ( x11-libs/wxGTK:2.8[X] )
+"
+DEPEND="${RDEPEND}
+	dev-ruby/rake
+"
+
+src_prepare() {
+	# Disable automagic curl dep used for online update checking
+	sed -i -e '/curl/d' configure.in
+	export CURL_CFLAGS="" CURL_LIBS=""
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	use pch || myconf+=" --disable-precompiled-headers"
+
+	if use wxwidgets ; then
+		WX_GTK_VER="2.8"
+		need-wxwidgets unicode
+		myconf+=" --with-wx-config=${WX_CONFIG}"
+	fi
+
+	econf \
+		$(use_enable lzo) \
+		$(use_enable bzip2 bz2) \
+		$(use_enable wxwidgets) \
+		$(use_enable debug) \
+		--disable-qt \
+		${myconf} \
+		--docdir=/usr/share/doc/${PF} \
+		--with-boost-regex=boost_regex \
+		--with-boost-filesystem=boost_filesystem \
+		--with-boost-system=boost_system
+}
+
+src_compile() {
+	rake || die "rake failed"
+}
+
+src_install() {
+	# Don't run strip while installing stuff, leave to portage the job.
+	DESTDIR="${D}" rake install || die
+
+	dodoc AUTHORS ChangeLog README TODO
+	doman doc/man/*.1
+
+	docompress -x /usr/share/doc/${PF}/guide
+}