Version bump, as requested by Joe Kappus in bug #538414. Depend on a basic icon theme as suggested by turtle in bug #539160.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key B5058F9A)

2 files changed, 77 insertions, 1 deletions

diff --git a/media-sound/audacious/ChangeLog b/media-sound/audacious/ChangeLog
index de009b646da8..1eddc4920566 100644
--- a/media-sound/audacious/ChangeLog
+++ b/media-sound/audacious/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/audacious
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.300 2015/01/29 18:52:25 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.301 2015/08/04 23:24:26 chainsaw Exp $
+
+*audacious-3.6.2 (04 Aug 2015)
+
+  04 Aug 2015; Tony Vroon <chainsaw@gentoo.org> +audacious-3.6.2.ebuild:
+  Version bump, as requested by Joe Kappus in bug #538414. Depend on a basic
+  icon theme as suggested by turtle in bug #539160.
 
   29 Jan 2015; Michał Górny <mgorny@gentoo.org> audacious-2.4.4.ebuild,
   audacious-2.5.4.ebuild:
diff --git a/media-sound/audacious/audacious-3.6.2.ebuild b/media-sound/audacious/audacious-3.6.2.ebuild
new file mode 100644
index 000000000000..8c718f54fa1e
--- /dev/null
+++ b/media-sound/audacious/audacious-3.6.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/audacious-3.6.2.ebuild,v 1.1 2015/08/04 23:24:26 chainsaw Exp $
+
+EAPI=5
+inherit eutils
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="!gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}.tar.bz2 )
+	 gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}-gtk3.tar.bz2 )
+	 mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux"
+
+IUSE="chardet nls gtk3 qt5"
+DOCS="AUTHORS"
+
+RDEPEND=">=dev-libs/dbus-glib-0.60
+	>=dev-libs/glib-2.28
+	>=x11-libs/cairo-1.2.6
+	>=x11-libs/pango-1.8.0
+	virtual/freedesktop-icon-theme
+	chardet? ( >=app-i18n/libguess-1.2 )
+	!gtk3? ( x11-libs/gtk+:2 )
+	gtk3? ( x11-libs/gtk+:3 )
+	qt5? ( dev-qt/qtcore:5
+	      dev-qt/qtgui:5
+	      dev-qt/qtwidgets:5 )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )"
+
+PDEPEND="~media-plugins/audacious-plugins-${PV}"
+
+src_unpack() {
+	default
+	if use gtk3 ; then
+		mv "${MY_P}-gtk3" "${MY_P}"
+	fi
+}
+
+src_configure() {
+	# D-Bus is a mandatory dependency, remote control,
+	# session management and some plugins depend on this.
+	# Building without D-Bus is *unsupported* and a USE-flag
+	# will not be added due to the bug reports that will result.
+	# Bugs #197894, #199069, #207330, #208606
+	econf \
+		--enable-dbus \
+		$(use_enable chardet) \
+		$(use_enable nls) \
+		$(use_enable qt5 qt)
+}
+
+src_install() {
+	default
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins "${WORKDIR}"/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}