USE="static-libs" and empty dependency_libs in libtool files wrt #386029. Respect environment CFLAGS with USE="debug" wrt #386027. Thanks to Agostino Sarubbo for reporting.

(Portage version: 2.2.0_alpha61/cvs/Linux x86_64)

2 files changed, 87 insertions, 1 deletions

diff --git a/media-sound/sox/ChangeLog b/media-sound/sox/ChangeLog
index 7b293d3b6017..3f91a1dca930 100644
--- a/media-sound/sox/ChangeLog
+++ b/media-sound/sox/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/sox
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/ChangeLog,v 1.127 2011/08/18 20:43:52 mattst88 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/ChangeLog,v 1.128 2011/10/07 15:17:40 ssuominen Exp $
+
+*sox-14.3.2-r1 (07 Oct 2011)
+
+  07 Oct 2011; Samuli Suominen <ssuominen@gentoo.org> +sox-14.3.2-r1.ebuild:
+  USE="static-libs" and empty dependency_libs in libtool files wrt #386029.
+  Respect environment CFLAGS with USE="debug" wrt #386027. Thanks to Agostino
+  Sarubbo for reporting.
 
   18 Aug 2011; Matt Turner <mattst88@gentoo.org> sox-14.3.0.ebuild,
   sox-14.3.1.ebuild, sox-14.3.2.ebuild:
diff --git a/media-sound/sox/sox-14.3.2-r1.ebuild b/media-sound/sox/sox-14.3.2-r1.ebuild
new file mode 100644
index 000000000000..10ab3ded68a5
--- /dev/null
+++ b/media-sound/sox/sox-14.3.2-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/sox/sox-14.3.2-r1.ebuild,v 1.1 2011/10/07 15:17:40 ssuominen Exp $
+
+EAPI=4
+inherit eutils flag-o-matic
+
+DESCRIPTION="The swiss army knife of sound processing programs"
+HOMEPAGE="http://sox.sourceforge.net"
+SRC_URI="mirror://sourceforge/sox/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="alsa amr ao debug encode ffmpeg flac id3tag ladspa mad ogg openmp oss png pulseaudio sndfile static-libs wavpack"
+
+# libtool required for libltdl
+RDEPEND=">=sys-devel/libtool-2.2.6b
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	encode? ( media-sound/lame )
+	flac? ( media-libs/flac )
+	mad? ( media-libs/libmad )
+	sndfile? ( media-libs/libsndfile )
+	ogg? ( media-libs/libvorbis	media-libs/libogg )
+	ao? ( media-libs/libao )
+	ffmpeg? ( virtual/ffmpeg )
+	ladspa? ( media-libs/ladspa-sdk )
+	>=media-sound/gsm-1.0.12-r1
+	id3tag? ( media-libs/libid3tag )
+	png? ( media-libs/libpng sys-libs/zlib )
+	pulseaudio? ( media-sound/pulseaudio )
+	wavpack? ( media-sound/wavpack )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	sed -i -e 's:CFLAGS="-g":CFLAGS="$CFLAGS -g":' configure || die #386027
+
+	epatch \
+		"${FILESDIR}"/${P}-uclibc.patch \
+		"${FILESDIR}"/${P}-ffmpeg.patch
+}
+
+src_configure() {
+	# Fixes wav segfaults. See Bug #35745.
+	append-flags -fsigned-char
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with alsa) \
+		$(use_enable debug) \
+		$(use_enable openmp gomp) \
+		$(use_with ao) \
+		$(use_with oss) \
+		$(use_with encode lame) \
+		$(use_with mad) \
+		$(use_with sndfile) \
+		$(use_with flac) \
+		$(use_with ogg oggvorbis) \
+		$(use_with ffmpeg) \
+		$(use_with ladspa) \
+		$(use_with id3tag) \
+		$(use_with amr amrwb) \
+		$(use_with amr amrnb) \
+		$(use_with png) \
+		$(use_with pulseaudio) \
+		$(use_with wavpack) \
+		--with-distro="Gentoo"
+}
+
+src_install() {
+	default
+	# libltdl is used for loading plugins, keeping libtool files with empty
+	# dependency_libs what otherwise would be -exec rm -f {} +
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+}