Version bump, remove old, fix pid file path in logrotate script

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 84F20B43)

4 files changed, 14 insertions, 211 deletions

diff --git a/media-sound/mpd/ChangeLog b/media-sound/mpd/ChangeLog
index 8fa9640a21da..eef2e8137309 100644
--- a/media-sound/mpd/ChangeLog
+++ b/media-sound/mpd/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/mpd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.348 2014/05/30 19:40:53 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/ChangeLog,v 1.349 2014/06/08 11:51:47 angelos Exp $
+
+*mpd-0.18.11 (08 Jun 2014)
+
+  08 Jun 2014; Christoph Mende <angelos@gentoo.org> +mpd-0.18.11.ebuild,
+  -mpd-0.18.10.ebuild, -mpd-0.18.9.ebuild, files/mpd.logrotate:
+  Version bump, remove old, fix pid file path in logrotate script
 
   30 May 2014; Markos Chandras <hwoarang@gentoo.org> mpd-0.18.10-r1.ebuild:
   opus actually needs ogg support as well. Bug #511586 by Nikoli
diff --git a/media-sound/mpd/files/mpd.logrotate b/media-sound/mpd/files/mpd.logrotate
index a19363174304..aae139d81afb 100644
--- a/media-sound/mpd/files/mpd.logrotate
+++ b/media-sound/mpd/files/mpd.logrotate
@@ -2,5 +2,6 @@
 	missingok
 	postrotate
 	[ -f /var/run/mpd.pid ] && cat /var/run/mpd.pid | xargs /bin/kill -HUP
+	[ -f /var/lib/mpd/pid ] && cat /var/lib/mpd/pid | xargs /bin/kill -HUP
 	endscript
 }
diff --git a/media-sound/mpd/mpd-0.18.10.ebuild b/media-sound/mpd/mpd-0.18.11.ebuild
index a3176b9fac2c..6bc6527b1e75 100644
--- a/media-sound/mpd/mpd-0.18.10.ebuild
+++ b/media-sound/mpd/mpd-0.18.11.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.18.10.ebuild,v 1.2 2014/05/17 14:47:02 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.18.11.ebuild,v 1.1 2014/06/08 11:51:47 angelos Exp $
 
 EAPI=5
 inherit eutils flag-o-matic linux-info multilib readme.gentoo systemd user
@@ -26,7 +26,8 @@ ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
 REQUIRED_USE="|| ( ${OUTPUT_PLUGINS} )
 	|| ( ${DECODER_PLUGINS} )
 	network? ( || ( ${ENCODER_PLUGINS} ) )
-	recorder? ( || ( ${ENCODER_PLUGINS} ) )"
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	opus? ( ogg )"
 
 RDEPEND="!<sys-cluster/mpich2-1.4_rc2
 	dev-libs/glib:2
@@ -91,10 +92,10 @@ pkg_setup() {
 
 src_prepare() {
 	DOC_CONTENTS="If you will be starting mpd via /etc/init.d/mpd, please make
-		sure that MPD's pid_file is unset."
+		sure that MPD's pid_file is _set_."
 
 	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
-	epatch "${FILESDIR}"/${PN}-0.16.conf.patch
+	epatch "${FILESDIR}"/${PN}-0.18.conf.patch
 
 	if has_version dev-libs/libcdio-paranoia; then
 		sed -i \
@@ -176,7 +177,7 @@ src_install() {
 	insinto /etc
 	newins doc/mpdconf.dist mpd.conf
 
-	newinitd "${FILESDIR}"/mpd.init mpd
+	newinitd "${FILESDIR}"/${PN}2.init ${PN}
 
 	if use unicode; then
 		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
diff --git a/media-sound/mpd/mpd-0.18.9.ebuild b/media-sound/mpd/mpd-0.18.9.ebuild
deleted file mode 100644
index 8c40e87c5a1c..000000000000
--- a/media-sound/mpd/mpd-0.18.9.ebuild
+++ /dev/null
@@ -1,205 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.18.9.ebuild,v 1.2 2014/05/17 14:47:02 swift Exp $
-
-EAPI=5
-inherit eutils flag-o-matic linux-info multilib readme.gentoo systemd user
-
-DESCRIPTION="The Music Player Daemon (mpd)"
-HOMEPAGE="http://www.musicpd.org"
-SRC_URI="http://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sh ~x86 ~x86-fbsd ~x64-macos"
-IUSE="adplug +alsa ao audiofile bzip2 cdio +curl debug faad +fifo +ffmpeg flac
-	fluidsynth gme +id3tag inotify ipv6 jack lame mms libmpdclient
-	libsamplerate +mad mikmod modplug mpg123 musepack +network ogg openal opus
-	oss pipe pulseaudio recorder selinux sid sndfile soundcloud sqlite systemd tcpd
-	twolame unicode vorbis wavpack wildmidi zeroconf zip"
-
-OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
-DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
-	modplug mpg123 musepack ogg flac sid vorbis wavpack wildmidi"
-ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
-
-REQUIRED_USE="|| ( ${OUTPUT_PLUGINS} )
-	|| ( ${DECODER_PLUGINS} )
-	network? ( || ( ${ENCODER_PLUGINS} ) )
-	recorder? ( || ( ${ENCODER_PLUGINS} ) )"
-
-RDEPEND="!<sys-cluster/mpich2-1.4_rc2
-	dev-libs/glib:2
-	adplug? ( media-libs/adplug )
-	alsa? ( media-sound/alsa-utils
-		media-libs/alsa-lib )
-	ao? ( media-libs/libao[alsa?,pulseaudio?] )
-	audiofile? ( media-libs/audiofile )
-	bzip2? ( app-arch/bzip2 )
-	cdio? ( || ( dev-libs/libcdio-paranoia <dev-libs/libcdio-0.90[-minimal] ) )
-	curl? ( net-misc/curl )
-	faad? ( media-libs/faad2 )
-	ffmpeg? ( virtual/ffmpeg )
-	flac? ( media-libs/flac[ogg?] )
-	fluidsynth? ( media-sound/fluidsynth )
-	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
-	id3tag? ( media-libs/libid3tag )
-	jack? ( media-sound/jack-audio-connection-kit )
-	lame? ( network? ( media-sound/lame ) )
-	libmpdclient? ( media-libs/libmpdclient )
-	libsamplerate? ( media-libs/libsamplerate )
-	mad? ( media-libs/libmad )
-	mikmod? ( media-libs/libmikmod:0 )
-	mms? ( media-libs/libmms )
-	modplug? ( media-libs/libmodplug )
-	mpg123? ( >=media-sound/mpg123-1.12.2 )
-	musepack? ( media-sound/musepack-tools )
-	network? ( >=media-libs/libshout-2
-		!lame? ( !vorbis? ( media-libs/libvorbis ) ) )
-	ogg? ( media-libs/libogg )
-	openal? ( media-libs/openal )
-	opus? ( media-libs/opus )
-	pulseaudio? ( media-sound/pulseaudio )
-	selinux? ( sec-policy/selinux-mpd )
-	sid? ( media-libs/libsidplay:2 )
-	sndfile? ( media-libs/libsndfile )
-	soundcloud? ( >=dev-libs/yajl-2 )
-	sqlite? ( dev-db/sqlite:3 )
-	systemd? ( sys-apps/systemd )
-	tcpd? ( sys-apps/tcp-wrappers )
-	twolame? ( media-sound/twolame )
-	vorbis? ( media-libs/libvorbis )
-	wavpack? ( media-sound/wavpack )
-	wildmidi? ( media-sound/wildmidi )
-	zeroconf? ( net-dns/avahi[dbus] )
-	zip? ( dev-libs/zziplib )"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-pkg_setup() {
-	use network || ewarn "Icecast and Shoutcast streaming needs networking."
-	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
-
-	enewuser mpd "" "" "/var/lib/mpd" audio
-
-	if use inotify; then
-		CONFIG_CHECK="~INOTIFY_USER"
-		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
-		linux-info_pkg_setup
-	fi
-}
-
-src_prepare() {
-	DOC_CONTENTS="If you will be starting mpd via /etc/init.d/mpd, please make
-		sure that MPD's pid_file is unset."
-
-	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
-	epatch "${FILESDIR}"/${PN}-0.16.conf.patch
-
-	if has_version dev-libs/libcdio-paranoia; then
-		sed -i \
-			-e 's:cdio/paranoia.h:cdio/paranoia/paranoia.h:' \
-			src/input/CdioParanoiaInputPlugin.cxx || die
-	fi
-}
-
-src_configure() {
-	local mpdconf="--disable-despotify --disable-documentation --disable-roar
-		--enable-largefile --enable-tcp --enable-un
-		--docdir=${EPREFIX}/usr/share/doc/${PF}"
-
-	if use network; then
-		mpdconf+=" --enable-shout $(use_enable vorbis vorbis-encoder)
-			--enable-httpd-output $(use_enable lame lame-encoder)
-			$(use_enable twolame twolame-encoder)
-			$(use_enable audiofile wave-encoder)"
-	else
-		mpdconf+=" --disable-shout --disable-vorbis-encoder
-			--disable-httpd-output --disable-lame-encoder
-			--disable-twolame-encoder --disable-wave-encoder"
-	fi
-
-	append-lfs-flags
-	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
-
-	econf \
-		$(use_enable alsa) \
-		$(use_enable ao) \
-		$(use_enable audiofile) \
-		$(use_enable bzip2) \
-		$(use_enable cdio cdio-paranoia) \
-		$(use_enable cdio iso9660) \
-		$(use_enable curl) \
-		$(use_enable debug) \
-		$(use_enable faad aac) \
-		$(use_enable ffmpeg) \
-		$(use_enable fifo) \
-		$(use_enable flac) \
-		$(use_enable fluidsynth) \
-		$(use_enable gme) \
-		$(use_enable id3tag id3) \
-		$(use_enable inotify) \
-		$(use_enable ipv6) \
-		$(use_enable jack) \
-		$(use_enable libmpdclient) \
-		$(use_enable libsamplerate lsr) \
-		$(use_enable mad) \
-		$(use_enable mikmod) \
-		$(use_enable mms) \
-		$(use_enable modplug) \
-		$(use_enable mpg123) \
-		$(use_enable musepack mpc) \
-		$(use_enable openal) \
-		$(use_enable opus) \
-		$(use_enable oss) \
-		$(use_enable pipe pipe-output) \
-		$(use_enable pulseaudio pulse) \
-		$(use_enable recorder recorder-output) \
-		$(use_enable sid sidplay) \
-		$(use_enable sndfile sndfile) \
-		$(use_enable soundcloud) \
-		$(use_enable sqlite) \
-		$(use_enable systemd systemd-daemon) \
-		$(use_enable tcpd libwrap) \
-		$(use_enable vorbis) \
-		$(use_enable wavpack) \
-		$(use_enable wildmidi) \
-		$(use_enable zip zzip) \
-		$(use_with zeroconf zeroconf avahi) \
-		"$(systemd_with_unitdir)" \
-		${mpdconf}
-}
-
-src_install() {
-	emake DESTDIR="${D}" install
-
-	insinto /etc
-	newins doc/mpdconf.dist mpd.conf
-
-	newinitd "${FILESDIR}"/mpd.init mpd
-
-	if use unicode; then
-		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
-			"${ED}"/etc/mpd.conf || die "sed failed"
-	fi
-
-	insinto /etc/logrotate.d
-	newins "${FILESDIR}"/${PN}.logrotate ${PN}
-
-	use prefix || diropts -m0755 -o mpd -g audio
-	dodir /var/lib/mpd
-	keepdir /var/lib/mpd
-	dodir /var/lib/mpd/music
-	keepdir /var/lib/mpd/music
-	dodir /var/lib/mpd/playlists
-	keepdir /var/lib/mpd/playlists
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	readme.gentoo_print_elog
-
-	# also change the homedir if the user has existed before
-	usermod -d "/var/lib/mpd" mpd
-}