Version bump to 1.3.1 for testing and remove deprecated ebuild

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 7B087241)

4 files changed, 90 insertions, 93 deletions

diff --git a/media-sound/beets/ChangeLog b/media-sound/beets/ChangeLog
index 6f3bf1acd302..cf285203b082 100644
--- a/media-sound/beets/ChangeLog
+++ b/media-sound/beets/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/beets
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/beets/ChangeLog,v 1.16 2013/10/20 19:27:42 sochotnicky Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/beets/ChangeLog,v 1.17 2013/11/05 22:42:59 sochotnicky Exp $
+
+*beets-1.3.1 (05 Nov 2013)
+
+  05 Nov 2013; Stanislav Ochotnicky <sochotnicky@gentoo.org>
+  -beets-1.0.0.ebuild, +beets-1.3.1.ebuild, metadata.xml:
+  Version bump to 1.3.1, remove 1.0.0
 
   20 Oct 2013; Stanislav Ochotnicky <sochotnicky@gentoo.org> metadata.xml:
   Move to maintainer-needed
diff --git a/media-sound/beets/beets-1.0.0.ebuild b/media-sound/beets/beets-1.0.0.ebuild
deleted file mode 100644
index eb30e3336e6f..000000000000
--- a/media-sound/beets/beets-1.0.0.ebuild
+++ /dev/null
@@ -1,92 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/beets/beets-1.0.0.ebuild,v 1.3 2013/08/11 21:48:08 aballier Exp $
-
-EAPI="4"
-
-PYTHON_DEPEND="2:2.6"
-PYTHON_USE_WITH="sqlite"
-SUPPORT_PYTHON_ABIS="1"
-#There a few test failures with 2.6, worth investigating
-RESTRICT_PYTHON_ABIS="2.5 3.* 2.7-pypy-*"
-
-inherit distutils eutils
-
-MY_PV=${PV/_rc/rc}
-MY_P=${PN}-${MY_PV}
-
-DESCRIPTION="A media library management system for obsessive-compulsive music geeks"
-SRC_URI="http://beets.googlecode.com/files/${MY_P}.tar.gz"
-HOMEPAGE="http://beets.radbox.org/"
-
-KEYWORDS="~amd64 ~x86"
-SLOT="0"
-LICENSE="MIT"
-IUSE="bpd chroma convert doc echonest_tempo lastgenre replaygain web"
-
-RDEPEND="
-	dev-python/munkres
-	dev-python/python-musicbrainz-ngs
-	dev-python/unidecode
-	media-libs/mutagen
-	bpd? ( dev-python/bluelet )
-	chroma? ( dev-python/pyacoustid )
-	convert? ( media-video/ffmpeg:0[encode] )
-	doc? ( dev-python/sphinx )
-	echonest_tempo? ( dev-python/pyechonest )
-	lastgenre? ( dev-python/pylast )
-	replaygain? ( || ( media-sound/mp3gain media-sound/aacgain ) )
-	web? ( dev-python/flask )
-"
-
-DEPEND="${RDEPEND}
-	dev-python/setuptools"
-
-S=${WORKDIR}/${MY_P}
-
-src_prepare() {
-	distutils_src_prepare
-
-	# we'll need this as long as portage doesn't have proper python
-	# namespace support (without this we would try to load modules from
-	# previous installation during updates)
-	use test && epatch "${FILESDIR}/${PN}-1.0_rc2-test-namespace.patch"
-
-	# remove plugins that do not have appropriate dependencies installed
-	for flag in bpd chroma convert echonest_tempo lastgenre replaygain web;do
-		if ! use $flag ; then
-			rm -r beetsplug/$flag* || \
-				die "Unable to remove $flag plugin"
-		fi
-	done
-
-	for flag in bpd lastgenre web;do
-		if ! use $flag ; then
-			sed -i "s:'beetsplug.$flag',::" setup.py || \
-				die "Unable to disable $flag plugin "
-		fi
-	done
-
-	use bpd || rm -f test/test_player.py
-
-}
-
-src_compile() {
-	distutils_src_compile
-	use doc && emake -C docs html
-}
-
-src_test() {
-	cd test
-	testing() {
-		PYTHONPATH="../build-${PYTHON_ABI}/lib" "$(PYTHON)" testall.py
-	}
-	python_execute_function testing
-}
-
-src_install() {
-	distutils_src_install
-	doman man/beet.1 man/beetsconfig.5
-
-	use doc && dohtml -r docs/_build/html/
-}
diff --git a/media-sound/beets/beets-1.3.1.ebuild b/media-sound/beets/beets-1.3.1.ebuild
new file mode 100644
index 000000000000..5dd0fb98aa90
--- /dev/null
+++ b/media-sound/beets/beets-1.3.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/beets/beets-1.3.1.ebuild,v 1.1 2013/11/05 22:42:59 sochotnicky Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 eutils
+
+MY_PV=${PV/_beta/-beta.}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="A media library management system for obsessive-compulsive music geeks"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+HOMEPAGE="http://beets.radbox.org/ http://pypi.python.org/pypi/beets"
+
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+LICENSE="MIT"
+IUSE="beatport bpd chroma convert doc discogs echonest_tempo lastgenre replaygain test web"
+
+RDEPEND="
+	dev-python/munkres[${PYTHON_USEDEP}]
+	>=dev-python/python-musicbrainz-ngs-0.4[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	>=media-libs/mutagen-0.22[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	beatport? ( dev-python/requests[${PYTHON_USEDEP}] )
+	bpd? ( dev-python/bluelet[${PYTHON_USEDEP}] )
+	chroma? ( dev-python/pyacoustid[${PYTHON_USEDEP}] )
+	convert? ( media-video/ffmpeg:0[encode] )
+	discogs? ( dev-python/discogs-client[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx )
+	echonest_tempo? ( dev-python/pyechonest[${PYTHON_USEDEP}] )
+	lastgenre? ( dev-python/pylast[${PYTHON_USEDEP}] )
+	replaygain? ( || ( media-sound/mp3gain media-sound/aacgain ) )
+	web? ( dev-python/flask[${PYTHON_USEDEP}] )
+"
+
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	# remove plugins that do not have appropriate dependencies installed
+	for flag in beatport bpd chroma convert discogs echonest_tempo lastgenre \
+				replaygain web;do
+		if ! use $flag ; then
+			rm -r beetsplug/$flag* || \
+				die "Unable to remove $flag plugin"
+		fi
+	done
+
+	for flag in bpd lastgenre web;do
+		if ! use $flag ; then
+			sed -i "s:'beetsplug.$flag',::" setup.py || \
+				die "Unable to disable $flag plugin "
+		fi
+	done
+
+	use bpd || rm -f test/test_player.py
+
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	cd test
+	"${PYTHON}" testall.py || die "Testsuite failed"
+}
+
+python_install_all() {
+	doman man/beet.1 man/beetsconfig.5
+
+	use doc && dohtml -r docs/_build/html/
+}
diff --git a/media-sound/beets/metadata.xml b/media-sound/beets/metadata.xml
index fdaf9586103b..c7ba9c055858 100644
--- a/media-sound/beets/metadata.xml
+++ b/media-sound/beets/metadata.xml
@@ -19,10 +19,12 @@ Because beets is designed as a library, it can do almost anything you can imagin
 If beets doesn’t do what you want yet, writing your own plugin is shockingly simple if you know a little Python.
 	</longdescription>
 	<use>
+		<flag name="beatport">Enable support for beetport.com API</flag>
 		<flag name="bpd">Enable support for <pkg>media-sound/mpd</pkg> server emulation</flag>
 		<flag name="chroma">Enable support for acoustic fingerprinting plugin using
 			(<pkg>media-libs/chromaprint</pkg>)</flag>
 		<flag name="convert">Enable support for the convert plugin which makes it possible to transcode files</flag>
+		<flag name="discogs">Enable support for the discogs API plugin</flag>
 		<flag name="echonest_tempo">Enable support for writing the BPM of a track into its metadata</flag>
        	<flag name="lastgenre">Enable support for importing music genres from last.fm tags</flag>
 		<flag name="replaygain">Enable support for Replay Gain metadata calculation during import</flag>