Bump to 1.71

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 565C32BC)

2 files changed, 65 insertions, 1 deletions

diff --git a/media-libs/leptonica/ChangeLog b/media-libs/leptonica/ChangeLog
index 06f16c18b1d1..b5147b98aa6d 100644
--- a/media-libs/leptonica/ChangeLog
+++ b/media-libs/leptonica/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/leptonica
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/leptonica/ChangeLog,v 1.15 2014/07/20 13:27:06 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/leptonica/ChangeLog,v 1.16 2014/07/29 13:07:48 tomka Exp $
+
+*leptonica-1.71 (29 Jul 2014)
+
+  29 Jul 2014; Thomas Kahle <tomka@gentoo.org> +leptonica-1.71.ebuild:
+  Bump to 1.71
 
   20 Jul 2014; Tobias Klausmann <klausman@gentoo.org> leptonica-1.70.ebuild:
   Keyworded on alpha, bug #510240
diff --git a/media-libs/leptonica/leptonica-1.71.ebuild b/media-libs/leptonica/leptonica-1.71.ebuild
new file mode 100644
index 000000000000..e8ce41334168
--- /dev/null
+++ b/media-libs/leptonica/leptonica-1.71.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/leptonica/leptonica-1.71.ebuild,v 1.1 2014/07/29 13:07:48 tomka Exp $
+
+EAPI=4
+
+inherit eutils autotools-utils
+
+DESCRIPTION="C library for image processing and analysis"
+HOMEPAGE="http://code.google.com/p/leptonica/"
+SRC_URI="http://www.leptonica.com/source/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="gif jpeg png tiff webp utils zlib static-libs"
+
+DEPEND="gif? ( media-libs/giflib )
+	jpeg? ( virtual/jpeg )
+	png? ( media-libs/libpng )
+	tiff? ( media-libs/tiff )
+	webp? ( media-libs/libwebp )
+	zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}"
+
+DOCS=( README version-notes )
+
+src_prepare() {
+	# unhtmlize docs
+	local X
+	for X in ${DOCS[@]}; do
+		awk '/<\/pre>/{s--} {if (s) print $0} /<pre>/{s++}' \
+			"${X}.html" > "${X}" || die 'awk failed'
+		rm -f -- "${X}.html"
+	done
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	# $(use_with webp libwebp) -> unknown
+	# so use-flag just for pulling dependencies
+	# zlib handling see bug 454890
+	local myeconfargs=(
+		$(use_with gif giflib)
+		$(use_with jpeg)
+		$(use_with png libpng)
+		$(use_with tiff libtiff)
+		$(use_enable utils programs)
+		$(use_enable static-libs static)
+	)
+	# libpng requires zlib:
+	if use png && ! use zlib ; then
+		# Ignore users non-sensical choice of -zlib
+		myeconfargs+=("--with-zlib")
+	else
+		myeconfargs+=( $(use_with zlib) )
+	fi
+	autotools-utils_src_configure
+}