Disable memphis support, as recommended by upstream, bug #549122.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 74 insertions, 1 deletions

diff --git a/media-libs/libchamplain/ChangeLog b/media-libs/libchamplain/ChangeLog
index dfd8908d0da9..bfb9b5289a4d 100644
--- a/media-libs/libchamplain/ChangeLog
+++ b/media-libs/libchamplain/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libchamplain
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/ChangeLog,v 1.62 2015/03/19 11:51:00 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/ChangeLog,v 1.63 2015/05/11 21:32:49 eva Exp $
+
+*libchamplain-0.12.10-r1 (11 May 2015)
+
+  11 May 2015; Gilles Dartiguelongue <eva@gentoo.org>
+  +libchamplain-0.12.10-r1.ebuild:
+  Disable memphis support, as recommended by upstream, bug #549122.
 
 *libchamplain-0.12.10 (19 Mar 2015)
 
diff --git a/media-libs/libchamplain/libchamplain-0.12.10-r1.ebuild b/media-libs/libchamplain/libchamplain-0.12.10-r1.ebuild
new file mode 100644
index 000000000000..cc6fcbba422a
--- /dev/null
+++ b/media-libs/libchamplain/libchamplain-0.12.10-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/libchamplain-0.12.10-r1.ebuild,v 1.1 2015/05/11 21:32:49 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG=no
+VALA_MIN_API_VERSION=0.14
+VALA_USE_DEPEND=vapigen
+
+inherit gnome2 vala
+
+DESCRIPTION="Clutter based world map renderer"
+HOMEPAGE="https://wiki.gnome.org/Projects/libchamplain"
+
+SLOT="0.12"
+LICENSE="LGPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="debug +gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	>=media-libs/clutter-1.12:1.0[introspection?]
+	media-libs/cogl:=
+	>=net-libs/libsoup-2.34:2.4
+	x11-libs/cairo
+	gtk? (
+		x11-libs/gtk+:3[introspection?]
+		media-libs/clutter-gtk:1.0 )
+	introspection? ( dev-libs/gobject-introspection )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# segfaults with vala:0.12
+# vala-0.14.2-r1 required for bug #402013
+
+src_prepare() {
+	# Fix documentation slotability
+	sed \
+		-e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-${SLOT}/" \
+		-i docs/reference/Makefile.{am,in} || die "sed (1) failed"
+	sed \
+		-e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-gtk-${SLOT}/" \
+		-i docs/reference-gtk/Makefile.{am,in} || die "sed (2) failed"
+	mv "${S}"/docs/reference/${PN}{,-${SLOT}}-docs.sgml || die "mv (1) failed"
+	mv "${S}"/docs/reference-gtk/${PN}-gtk{,-${SLOT}}-docs.sgml || die "mv (2) failed"
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Vala demos are only built, so just disable them
+	gnome2_src_configure \
+		--disable-maemo \
+		--disable-memphis \
+		--disable-static \
+		--disable-vala-demos \
+		$(use_enable debug) \
+		$(use_enable gtk) \
+		$(use_enable introspection)
+}