Version bump (bug #482926).

(Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 68 insertions, 1 deletions

diff --git a/media-libs/libraw/ChangeLog b/media-libs/libraw/ChangeLog
index 3e1ba9498b28..3b5153c8bc93 100644
--- a/media-libs/libraw/ChangeLog
+++ b/media-libs/libraw/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libraw
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v 1.60 2013/08/27 15:43:04 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v 1.61 2013/08/29 20:27:54 radhermit Exp $
+
+*libraw-0.15.4 (29 Aug 2013)
+
+  29 Aug 2013; Tim Harder <radhermit@gentoo.org> +libraw-0.15.4.ebuild:
+  Version bump (bug #482926).
 
   27 Aug 2013; Michael Palimaka <kensington@gentoo.org> libraw-0.15.2.ebuild,
   libraw-0.15.3.ebuild:
diff --git a/media-libs/libraw/libraw-0.15.4.ebuild b/media-libs/libraw/libraw-0.15.4.ebuild
new file mode 100644
index 000000000000..81f7ad8ed03a
--- /dev/null
+++ b/media-libs/libraw/libraw-0.15.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/libraw-0.15.4.ebuild,v 1.1 2013/08/29 20:27:54 radhermit Exp $
+
+EAPI=5
+
+inherit eutils autotools toolchain-funcs
+
+MY_PV=${PV/_b/-B}
+MY_P=LibRaw-${MY_PV}
+
+DESCRIPTION="LibRaw is a library for reading RAW files obtained from digital photo cameras"
+HOMEPAGE="http://www.libraw.org/"
+SRC_URI="http://www.libraw.org/data/${MY_P}.tar.gz
+	demosaic? (	http://www.libraw.org/data/LibRaw-demosaic-pack-GPL2-${MY_PV}.tar.gz
+		http://www.libraw.org/data/LibRaw-demosaic-pack-GPL3-${MY_PV}.tar.gz )"
+
+# Libraw also has it's own license, which is a pdf file and
+# can be obtained from here:
+# http://www.libraw.org/data/LICENSE.LibRaw.pdf
+LICENSE="LGPL-2.1 CDDL GPL-2 GPL-3"
+SLOT="0/9" # subslot = libraw soname version
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="demosaic examples jpeg jpeg2k +lcms openmp static-libs"
+
+RDEPEND="jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/jasper )
+	lcms? ( media-libs/lcms:2 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( Changelog.txt README )
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.13.4-docs.patch
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable openmp) \
+		$(use_enable jpeg) \
+		$(use_enable jpeg2k jasper) \
+		$(use_enable lcms) \
+		$(use_enable examples) \
+		$(use_enable demosaic demosaic-pack-gpl2) \
+		$(use_enable demosaic demosaic-pack-gpl3)
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}