Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 72 insertions, 1 deletions

diff --git a/media-libs/libraw/ChangeLog b/media-libs/libraw/ChangeLog
index f294f171b18a..dfd94c14d7ba 100644
--- a/media-libs/libraw/ChangeLog
+++ b/media-libs/libraw/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libraw
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v 1.69 2013/10/20 11:23:28 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v 1.70 2013/11/08 09:42:43 radhermit Exp $
+
+*libraw-0.16.0_alpha3 (08 Nov 2013)
+
+  08 Nov 2013; Tim Harder <radhermit@gentoo.org> +libraw-0.16.0_alpha3.ebuild:
+  Version bump.
 
   20 Oct 2013; Tim Harder <radhermit@gentoo.org>
   files/libraw-0.16.0_alpha2-automagic-jasper.patch,
diff --git a/media-libs/libraw/libraw-0.16.0_alpha3.ebuild b/media-libs/libraw/libraw-0.16.0_alpha3.ebuild
new file mode 100644
index 000000000000..8783ef72afa4
--- /dev/null
+++ b/media-libs/libraw/libraw-0.16.0_alpha3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/libraw-0.16.0_alpha3.ebuild,v 1.1 2013/11/08 09:42:43 radhermit Exp $
+
+EAPI=5
+
+inherit cmake-multilib toolchain-funcs
+
+MY_PN=LibRaw
+MY_PV=${PV/_a/-A}
+MY_P=${MY_PN}-${MY_PV}
+
+DESCRIPTION="LibRaw is a library for reading RAW files obtained from digital photo cameras"
+HOMEPAGE="http://www.libraw.org/"
+SRC_URI="http://www.libraw.org/data/${MY_P}.tar.gz
+	demosaic? (
+		http://www.libraw.org/data/LibRaw-demosaic-pack-GPL2-${MY_PV}.tar.gz
+		http://www.libraw.org/data/LibRaw-demosaic-pack-GPL3-${MY_PV}.tar.gz
+	)"
+
+# Libraw also has it's own license, which is a pdf file and
+# can be obtained from here:
+# http://www.libraw.org/data/LICENSE.LibRaw.pdf
+LICENSE="LGPL-2.1 CDDL GPL-2 GPL-3"
+SLOT="0/10" # subslot = libraw soname version
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="demosaic examples jpeg jpeg2k +lcms openmp"
+
+RDEPEND="jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
+	jpeg2k? ( media-libs/jasper[${MULTILIB_USEDEP}] )
+	lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( Changelog.txt README )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.16.0_alpha2-docs.patch
+	"${FILESDIR}"/${PN}-0.16.0_alpha2-automagic-jasper.patch
+	"${FILESDIR}"/${PN}-0.16.0_alpha2-libdir.patch
+	"${FILESDIR}"/${PN}-0.16.0_alpha2-lcms2-first.patch
+	"${FILESDIR}"/${PN}-0.16.0_alpha2-custom-demosaic-paths.patch
+)
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable openmp OPENMP)
+		$(cmake-utils_use_enable jpeg JPEG)
+		$(cmake-utils_use_enable jpeg2k JASPER)
+		$(cmake-utils_use_enable lcms LCMS)
+		$(cmake-utils_use_enable examples EXAMPLES)
+		$(cmake-utils_use_enable demosaic DEMOSAIC_PACK_GPL2)
+		$(cmake-utils_use_enable demosaic DEMOSAIC_PACK_GPL3)
+		-DDEMOSAIC_PACK_GPL2_PATH="${WORKDIR}/${MY_PN}-demosaic-pack-GPL2-${MY_PV}"
+		-DDEMOSAIC_PACK_GPL3_PATH="${WORKDIR}/${MY_PN}-demosaic-pack-GPL3-${MY_PV}"
+	)
+	cmake-multilib_src_configure
+}