new release

1 files changed, 78 insertions, 0 deletions

diff --git a/media-libs/gstreamer/gstreamer-0.6.4.ebuild b/media-libs/gstreamer/gstreamer-0.6.4.ebuild
new file mode 100644
index 000000000000..af5d39f47804
--- /dev/null
+++ b/media-libs/gstreamer/gstreamer-0.6.4.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2003 Gentoo Technologies, Inc.
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-0.6.4.ebuild,v 1.1 2003/10/23 21:56:11 foser Exp $
+
+inherit eutils flag-o-matic libtool gnome.org
+
+# Create a major/minor combo for our SLOT and executables suffix
+PVP=($(echo " $PV " | sed 's:[-\._]: :g'))
+PV_MAJ_MIN=${PVP[0]}.${PVP[1]}
+
+DESCRIPTION="Streaming media framework"
+HOMEPAGE="http://gstreamer.sourceforge.net"
+LICENSE="LGPL-2"
+
+SLOT=${PV_MAJ_MIN}
+KEYWORDS="~x86 ~ppc ~sparc ~alpha ~amd64"
+IUSE="doc"
+
+RDEPEND=">=dev-libs/glib-2.0.4
+	>=dev-libs/libxml2-2.4.9
+	>=dev-libs/popt-1.6.1"
+
+DEPEND="${RDEPEND}
+	>=sys-apps/sed-4
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc
+		app-text/xmlto )"
+
+src_unpack() {
+
+	unpack ${A}
+
+	# docs hack, disable dirs without html output
+	cd ${S}/docs
+	mv Makefile.in Makefile.in.old
+	sed -e "s:faq manual pwg::" Makefile.in.old > Makefile.in
+
+}
+
+src_compile() {
+
+	elibtoolize
+
+	strip-flags
+	replace-flags "-O3" "-O2"
+
+	# docs hack, circumvent xmltex check
+	HAVE_XMLTEX=1 econf \
+		--program-suffix=-${PV_MAJ_MIN} \
+		--with-configdir=/etc/gstreamer \
+		--disable-tests  \
+		--disable-examples \
+		`use_enable doc docs-build` \
+		|| die "./configure failed"
+
+	# On alpha and amd64 some innocuous warnings are spit out that break the
+	# build because of -Werror
+	use alpha && find . -name Makefile | xargs sed -i -e 's/-Werror//g'
+	use amd64 && find . -name Makefile | xargs sed -i -e 's/-Werror//g'
+
+	emake || die "compile failed"
+
+}
+
+src_install() {
+
+	einstall || die
+
+	dodoc AUTHORS ChangeLog COPYING* DEVEL \
+		NEWS README RELEASE REQUIREMENTS TODO
+
+}
+
+pkg_postinst() {
+
+	gst-register-${PV_MAJ_MIN}
+
+}