Version bump.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 54 insertions, 1 deletions

diff --git a/media-gfx/pngquant/ChangeLog b/media-gfx/pngquant/ChangeLog
index e55d1e3ffbed..469898a82eec 100644
--- a/media-gfx/pngquant/ChangeLog
+++ b/media-gfx/pngquant/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/pngquant
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/pngquant/ChangeLog,v 1.6 2014/03/15 11:42:55 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/pngquant/ChangeLog,v 1.7 2014/04/25 08:35:26 radhermit Exp $
+
+*pngquant-2.2.0 (25 Apr 2014)
+
+  25 Apr 2014; Tim Harder <radhermit@gentoo.org> +pngquant-2.2.0.ebuild:
+  Version bump.
 
 *pngquant-2.1.0 (15 Mar 2014)
 
diff --git a/media-gfx/pngquant/pngquant-2.2.0.ebuild b/media-gfx/pngquant/pngquant-2.2.0.ebuild
new file mode 100644
index 000000000000..572bc35bd6a8
--- /dev/null
+++ b/media-gfx/pngquant/pngquant-2.2.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/pngquant/pngquant-2.2.0.ebuild,v 1.1 2014/04/25 08:35:26 radhermit Exp $
+
+EAPI=5
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="a command-line utility for converting 24/32-bit PNG images to paletted (8-bit) PNGs"
+HOMEPAGE="http://pngquant.org/"
+SRC_URI="http://pngquant.org/${P}-src.tar.bz2"
+
+LICENSE="HPND rwpng"
+SLOT=0
+KEYWORDS="~amd64 ~x86"
+IUSE="debug openmp sse2"
+
+RDEPEND="media-libs/libpng:0=
+	sys-libs/zlib:="
+DEPEND=${RDEPEND}
+
+src_prepare() {
+	# Failure in upstream logic. Otherwise we lose the -I and -L flags
+	# from Makefile.
+	sed -i \
+		-e 's:CFLAGS ?=:CFLAGS +=:' \
+		-e 's:LDFLAGS ?=:LDFLAGS +=:' \
+		Makefile || die
+}
+
+src_compile() {
+	use debug || append-cflags -DNDEBUG
+	use sse2 && append-cflags -DUSE_SSE=1
+
+	local openmp
+	if use openmp && tc-has-openmp; then
+		append-cflags -fopenmp
+		openmp="-lgomp"
+	fi
+
+	tc-export CC
+	emake CFLAGSOPT="" OPENMPFLAGS="${openmp}"
+}
+
+src_install() {
+	dobin ${PN}
+	doman ${PN}.1
+	dodoc CHANGELOG README.md
+}