Version bump. Add explicit deps on glib and pango and slots for tiff and libpng.

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

3 files changed, 132 insertions, 5 deletions

diff --git a/media-gfx/darktable/ChangeLog b/media-gfx/darktable/ChangeLog
index acb8c6c76090..45b8e9a37b6f 100644
--- a/media-gfx/darktable/ChangeLog
+++ b/media-gfx/darktable/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/darktable
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.37 2013/02/07 22:25:40 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/ChangeLog,v 1.38 2013/02/09 21:15:34 radhermit Exp $
+
+*darktable-1.1.3 (09 Feb 2013)
+
+  09 Feb 2013; Tim Harder <radhermit@gentoo.org> +darktable-1.1.3.ebuild,
+  darktable-9999.ebuild:
+  Version bump. Add explicit deps on glib and pango and slots for tiff and
+  libpng.
 
   07 Feb 2013; Ulrich Müller <ulm@gentoo.org> darktable-1.1.1.ebuild,
   darktable-1.1.2.ebuild, darktable-1.1.2-r1.ebuild:
diff --git a/media-gfx/darktable/darktable-1.1.3.ebuild b/media-gfx/darktable/darktable-1.1.3.ebuild
new file mode 100644
index 000000000000..a4bf7dfae809
--- /dev/null
+++ b/media-gfx/darktable/darktable-1.1.3.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-1.1.3.ebuild,v 1.1 2013/02/09 21:15:34 radhermit Exp $
+
+EAPI="5"
+
+inherit cmake-utils toolchain-funcs gnome2-utils fdo-mime pax-utils eutils
+
+DESCRIPTION="A virtual lighttable and darkroom for photographers"
+HOMEPAGE="http://www.darktable.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	doc? ( mirror://sourceforge/${PN}/${PN}-usermanual-1.1.2.pdf )"
+
+LICENSE="GPL-3 CC-BY-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="colord doc facebook flickr geo gnome-keyring gphoto2 kde
+nls opencl openmp pax_kernel +rawspeed +slideshow"
+
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.28:2
+	dev-libs/libxml2:2
+	colord? ( x11-misc/colord )
+	facebook? ( dev-libs/json-glib )
+	flickr? ( media-libs/flickcurl )
+	geo? ( net-libs/libsoup:2.4 )
+	gnome-keyring? ( gnome-base/gnome-keyring )
+	gnome-base/librsvg:2
+	gphoto2? ( media-libs/libgphoto2 )
+	kde? (
+		dev-libs/dbus-glib
+		kde-base/kwalletd
+	)
+	media-gfx/exiv2[xmp]
+	media-libs/lcms:2
+	>=media-libs/lensfun-0.2.3
+	media-libs/libpng:0
+	media-libs/openexr
+	media-libs/tiff:0
+	net-misc/curl
+	opencl? ( virtual/opencl )
+	slideshow? (
+		media-libs/libsdl
+		virtual/glu
+		virtual/opengl
+	)
+	virtual/jpeg
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:2
+	x11-libs/pango"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+pkg_pretend() {
+	if use openmp ; then
+		tc-has-openmp || die "Please switch to an openmp compatible compiler"
+	fi
+}
+
+src_prepare() {
+	sed -e "s:\(/share/doc/\)darktable:\1${PF}:" \
+		-e "s:LICENSE::" \
+		-i doc/CMakeLists.txt || die
+
+	epatch_user
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_use colord COLORD)
+		$(cmake-utils_use_use facebook GLIBJSON)
+		$(cmake-utils_use_use flickr FLICKR)
+		$(cmake-utils_use_use geo GEO)
+		$(cmake-utils_use_use gnome-keyring GNOME_KEYRING)
+		$(cmake-utils_use_use gphoto2 CAMERA_SUPPORT)
+		$(cmake-utils_use_use kde KWALLET)
+		$(cmake-utils_use_use nls NLS)
+		$(cmake-utils_use_use opencl OPENCL)
+		$(cmake-utils_use_use openmp OPENMP)
+		$(cmake-utils_use !rawspeed DONT_USE_RAWSPEED)
+		$(cmake-utils_use_build slideshow SLIDESHOW)
+		-DCUSTOM_CFLAGS=ON
+		-DINSTALL_IOP_EXPERIMENTAL=ON
+		-DINSTALL_IOP_LEGACY=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	use doc && dodoc "${DISTDIR}"/${PN}-usermanual-${PV}.pdf
+
+	if use pax_kernel && use opencl ; then
+		pax-mark Cm "${ED}"/usr/bin/${PN} || die
+		eqawarn "USE=pax_kernel is set meaning that ${PN} will be run"
+		eqawarn "under a PaX enabled kernel. To do so, the ${PN} binary"
+		eqawarn "must be modified and this *may* lead to breakage! If"
+		eqawarn "you suspect that ${PN} is broken by this modification,"
+		eqawarn "please open a bug."
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	fdo-mime_desktop_database_update
+}
diff --git a/media-gfx/darktable/darktable-9999.ebuild b/media-gfx/darktable/darktable-9999.ebuild
index 703d192e4cff..98015192fc8d 100644
--- a/media-gfx/darktable/darktable-9999.ebuild
+++ b/media-gfx/darktable/darktable-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v 1.6 2013/01/24 02:32:38 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/darktable/darktable-9999.ebuild,v 1.7 2013/02/09 21:15:34 radhermit Exp $
 
 EAPI="5"
 
@@ -19,6 +19,7 @@ nls opencl openmp pax_kernel +rawspeed +slideshow"
 
 CDEPEND="
 	dev-db/sqlite:3
+	>=dev-libs/glib-2.28:2
 	dev-libs/libxml2:2
 	colord? ( x11-misc/colord )
 	facebook? ( dev-libs/json-glib )
@@ -32,9 +33,9 @@ CDEPEND="
 	media-gfx/exiv2[xmp]
 	media-libs/lcms:2
 	>=media-libs/lensfun-0.2.3
-	media-libs/libpng
+	media-libs/libpng:0
 	media-libs/openexr
-	media-libs/tiff
+	media-libs/tiff:0
 	net-misc/curl
 	opencl? ( virtual/opencl )
 	slideshow? (
@@ -45,7 +46,8 @@ CDEPEND="
 	virtual/jpeg
 	x11-libs/cairo
 	x11-libs/gdk-pixbuf:2
-	x11-libs/gtk+:2"
+	x11-libs/gtk+:2
+	x11-libs/pango"
 RDEPEND="${CDEPEND}
 	kde? ( kde-base/kwalletd )"
 DEPEND="${CDEPEND}