add patch that fixes loading of Fluxbox, E17, Openbox and perhaps others, see http://lxnay.wordpress.com/2011/07/03/lxdm-the-wannabe-login-manager for more details

(Portage version: 2.2.0_alpha37/cvs/Linux x86_64)

1 files changed, 63 insertions, 0 deletions

diff --git a/lxde-base/lxdm/lxdm-0.3.0-r3.ebuild b/lxde-base/lxdm/lxdm-0.3.0-r3.ebuild
new file mode 100644
index 000000000000..ca0516933426
--- /dev/null
+++ b/lxde-base/lxdm/lxdm-0.3.0-r3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxdm/lxdm-0.3.0-r3.ebuild,v 1.1 2011/07/03 10:02:29 lxnay Exp $
+
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="LXDE Display Manager"
+HOMEPAGE="http://lxde.org"
+SRC_URI="mirror://sourceforge/lxde/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+consolekit nls"
+
+COMMON_DEPEND="sys-libs/pam
+	x11-libs/gtk+:2
+	consolekit? ( sys-auth/consolekit )
+	nls? ( sys-devel/gettext )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40
+	dev-util/pkgconfig"
+RDEPEND="${COMMON_DEPEND}
+	gnome-base/librsvg"
+
+src_configure() {
+	econf --with-x $(use_enable nls) || die "econf failed"
+}
+
+src_prepare() {
+	# There is consolekit
+	epatch "${FILESDIR}/${P}-pam_console-disable.patch"
+	use consolekit || epatch "${FILESDIR}/${P}-consolekit-disable.patch"
+
+	epatch "${FILESDIR}"/${P}-properly-load-session-settings-using-dmrc-entry-as-pointer-for-xsessions-dir-file.patch
+
+	# this replaces the bootstrap/autogen script in most packages
+	eautoreconf
+
+	# process LINGUAS
+	if use nls; then
+		einfo "Running intltoolize ..."
+		intltoolize --force --copy --automake || die
+		strip-linguas -i "${S}/po" || die
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS README TODO || die
+	# install xinitrc
+	exeinto /etc/lxdm
+	doexe "${FILESDIR}"/xinitrc || die
+}
+
+pkg_postinst() {
+	echo
+	elog "LXDM is in early stage of development."
+	echo
+}