Version bump wrt bug #514678.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

2 files changed, 77 insertions, 2 deletions

diff --git a/kde-misc/tellico/ChangeLog b/kde-misc/tellico/ChangeLog
index a88d1e369caf..82b388d6f89c 100644
--- a/kde-misc/tellico/ChangeLog
+++ b/kde-misc/tellico/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-misc/tellico
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-misc/tellico/ChangeLog,v 1.126 2013/08/28 11:49:11 kensington Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/kde-misc/tellico/ChangeLog,v 1.127 2014/06/25 17:24:54 kensington Exp $
+
+*tellico-2.3.9 (25 Jun 2014)
+
+  25 Jun 2014; Michael Palimaka <kensington@gentoo.org> +tellico-2.3.9.ebuild:
+  Version bump wrt bug #514678.
 
   28 Aug 2013; Michael Palimaka <kensington@gentoo.org> -tellico-2.3.7.ebuild:
   Remove old.
diff --git a/kde-misc/tellico/tellico-2.3.9.ebuild b/kde-misc/tellico/tellico-2.3.9.ebuild
new file mode 100644
index 000000000000..4423de3decf8
--- /dev/null
+++ b/kde-misc/tellico/tellico-2.3.9.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-misc/tellico/tellico-2.3.9.ebuild,v 1.1 2014/06/25 17:24:54 kensington Exp $
+
+EAPI=5
+
+KDE_LINGUAS="bg bs ca ca@valencia cs da de el en_GB eo es et eu fi fr ga gl hu
+ia it ja kk lt mr ms nb nds nl nn pl pt pt_BR ro ru sk sl sv tr ug uk zh_CN
+zh_TW"
+KDE_HANDBOOK="optional"
+inherit kde4-base
+
+DESCRIPTION="A collection manager for the KDE environment"
+HOMEPAGE="http://tellico-project.org/"
+SRC_URI="http://tellico-project.org/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="4"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="addressbook cddb debug pdf scanner taglib v4l xmp yaz"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	dev-libs/qjson
+	$(add_kdebase_dep kdelibs 'semantic-desktop(+)')
+	media-libs/qimageblitz
+	dev-qt/qtdbus:4
+	addressbook? ( $(add_kdebase_dep kdepimlibs) )
+	cddb? ( $(add_kdebase_dep libkcddb) )
+	pdf? ( app-text/poppler[qt4] )
+	scanner? ( $(add_kdebase_dep libksane) )
+	taglib? ( >=media-libs/taglib-1.5 )
+	v4l? ( >=media-libs/libv4l-0.8.3 )
+	xmp? ( >=media-libs/exempi-2 )
+	yaz? ( >=dev-libs/yaz-2 )
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+"
+
+# tests need network access and well-defined server responses
+RESTRICT="test"
+
+DOCS=( AUTHORS ChangeLog README )
+
+src_prepare() {
+	# KDE_LINGUAS is also used to install appropriate handbooks
+	# since there is no en_US 'translation', it cannot be added
+	# hence making this impossible to install
+	mv doc/en_US doc/en || die "doc move failed"
+	sed -i -e 's/en_US/en/' doc/CMakeLists.txt || die "sed failed"
+
+	kde4-base_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable v4l WEBCAM)
+		$(cmake-utils_use_with xmp Exempi)
+		$(cmake-utils_use_with scanner KSane)
+		$(cmake-utils_use_with cddb KdeMultimedia)
+		$(cmake-utils_use_with addressbook KdepimLibs)
+		$(cmake-utils_use_with pdf PopplerQt4)
+		$(cmake-utils_use_with taglib)
+		$(cmake-utils_use_with yaz)
+	)
+
+	kde4-base_src_configure
+}