version bump (bug #537196)

(Portage version: 2.2.14/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 105 insertions, 2 deletions

diff --git a/games-roguelike/angband/ChangeLog b/games-roguelike/angband/ChangeLog
index c0459cad353a..fc5dabbbc371 100644
--- a/games-roguelike/angband/ChangeLog
+++ b/games-roguelike/angband/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-roguelike/angband
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v 1.54 2014/09/19 19:04:20 mr_bones_ Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/ChangeLog,v 1.55 2015/01/21 06:30:18 mr_bones_ Exp $
+
+*angband-3.5.1 (21 Jan 2015)
+
+  21 Jan 2015; Michael Sterrett <mr_bones_@gentoo.org> +angband-3.5.1.ebuild:
+  version bump (bug #537196)
 
   19 Sep 2014; Michael Sterrett <mr_bones_@gentoo.org> angband-3.4.1.ebuild:
   EAPI=5; work around X_PRE_LIBS (bug #523214)
diff --git a/games-roguelike/angband/angband-3.5.1.ebuild b/games-roguelike/angband/angband-3.5.1.ebuild
new file mode 100644
index 000000000000..1274f2687181
--- /dev/null
+++ b/games-roguelike/angband/angband-3.5.1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/angband/angband-3.5.1.ebuild,v 1.1 2015/01/21 06:30:18 mr_bones_ Exp $
+
+EAPI=5
+inherit eutils versionator games
+
+MAJOR_PV=$(get_version_component_range 1-2)
+MY_P=${PN}-v${PV}
+
+DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
+HOMEPAGE="http://rephial.org/"
+SRC_URI="http://rephial.org/downloads/${MAJOR_PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="ncurses sdl +sound X"
+
+RDEPEND="X? ( x11-libs/libX11 )
+	!ncurses? ( !X? ( !sdl? ( sys-libs/ncurses ) ) )
+	ncurses? ( sys-libs/ncurses )
+	sdl? ( media-libs/libsdl[video,X]
+		media-libs/sdl-ttf
+		media-libs/sdl-image
+		sound? ( media-libs/sdl-mixer[mp3]
+			media-libs/libsdl[sound] ) )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	# fix paths
+	sed -i \
+		-e '/libpath/s#datarootdir#datadir#' \
+		-e '/X_PRE_LIBS/s:-lSM -lICE::' \
+		configure || die
+
+	sed -i \
+		-e "/^.SILENT/d" \
+		mk/buildsys.mk.in || die
+}
+
+src_configure() {
+	local myconf
+
+	if use sdl; then
+		myconf="$(use_enable sound sdl-mixer)"
+	else
+		myconf="--disable-sdl-mixer"
+	fi
+
+	egamesconf \
+		--bindir="${GAMES_BINDIR}" \
+		--with-private-dirs \
+		$(use_enable X x11) \
+		$(use_enable sdl) \
+		$(use_enable ncurses curses) \
+		$(use !sdl && use !ncurses && use !X && \
+			echo --enable-curses) \
+		${myconf}
+}
+
+src_install() {
+	DOCS=( changes.txt faq.txt readme.txt thanks.txt )
+
+	default
+
+	# Edit files are now system config files in Angband, but
+	# users will be hidden from applying updates by default
+	echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/edit/\"" \
+		> "${T}"/99${PN}
+	doenvd "${T}"/99${PN} || die
+
+	# Create desktop entries if required.
+	ICON_LOC="${GAMES_DATADIR}/${PN}/xtra/icon/att-32.png"
+	if use X; then
+		make_desktop_entry "angband -mx11" "Angband (X11)" "${ICON_LOC}"
+	fi
+
+	if use sdl; then
+		make_desktop_entry "angband -msdl" "Angband (SDL)" "${ICON_LOC}"
+	fi
+
+	use ncurses || rm -rf "${D}${GAMES_DATADIR}/${PN}/xtra/graf"
+	use sound || rm -rf "${D}${GAMES_DATADIR}/${PN}/xtra/sound"
+
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	echo
+	elog "Angband now uses private savefiles instead of system-wide ones"
+	elog "This version of Angband is not compatible with the save files"
+	elog "of previous versions"
+	echo
+
+	games_pkg_postinst
+}