Add live ebuild.

(Portage version: 2.2.0_alpha124/cvs/Linux x86_64)

2 files changed, 88 insertions, 1 deletions

diff --git a/games-emulation/vbam/ChangeLog b/games-emulation/vbam/ChangeLog
index fece0d69dbda..2f7ede77eb7c 100644
--- a/games-emulation/vbam/ChangeLog
+++ b/games-emulation/vbam/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-emulation/vbam
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/vbam/ChangeLog,v 1.12 2012/07/31 23:01:05 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/vbam/ChangeLog,v 1.13 2012/09/08 23:22:51 radhermit Exp $
+
+*vbam-9999 (08 Sep 2012)
+
+  08 Sep 2012; Tim Harder <radhermit@gentoo.org> +vbam-9999.ebuild:
+  Add live ebuild.
 
   31 Jul 2012; Julian Ospald <hasufell@gentoo.org> vbam-1.8.0.1009-r1.ebuild,
   vbam-1.8.0.1090.ebuild:
diff --git a/games-emulation/vbam/vbam-9999.ebuild b/games-emulation/vbam/vbam-9999.ebuild
new file mode 100644
index 000000000000..c16f09f37110
--- /dev/null
+++ b/games-emulation/vbam/vbam-9999.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/vbam/vbam-9999.ebuild,v 1.1 2012/09/08 23:22:51 radhermit Exp $
+
+EAPI=4
+WX_GTK_VER="2.8"
+
+inherit cmake-utils wxwidgets subversion games
+
+ESVN_REPO_URI="https://vbam.svn.sourceforge.net/svnroot/vbam/trunk"
+
+DESCRIPTION="Game Boy, GBC, and GBA emulator forked from VisualBoyAdvance"
+HOMEPAGE="http://vba-m.ngemu.com"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="cairo ffmpeg gtk link lirc nls openal +sdl wxwidgets"
+REQUIRED_USE="|| ( sdl gtk wxwidgets )"
+
+RDEPEND=">=media-libs/libpng-1.4
+	media-libs/libsdl[joystick]
+	link? ( media-libs/libsfml )
+	sys-libs/zlib
+	virtual/opengl
+	ffmpeg? ( virtual/ffmpeg )
+	gtk? ( >=dev-cpp/glibmm-2.4.0:2
+		>=dev-cpp/gtkmm-2.4.0:2.4
+		>=dev-cpp/gtkglextmm-1.2.0 )
+	lirc? ( app-misc/lirc )
+	nls? ( virtual/libintl )
+	wxwidgets? (
+		cairo? ( x11-libs/cairo )
+		openal? ( media-libs/openal )
+		x11-libs/wxGTK:2.8[X,opengl]
+	)"
+DEPEND="${RDEPEND}
+	x86? ( || ( dev-lang/nasm dev-lang/yasm ) )
+	nls? ( sys-devel/gettext )
+	virtual/pkgconfig"
+
+src_prepare() {
+	# Fix issue with zlib-1.2.5.1 macros (bug #383179)
+	sed -i '1i#define OF(x) x' src/common/memgzio.c || die
+
+	sed -i -e "s:\(DESTINATION\) bin:\1 ${GAMES_BINDIR}:" CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_enable cairo CAIRO)
+		$(cmake-utils_use_enable ffmpeg FFMPEG)
+		$(cmake-utils_use_enable gtk GTK)
+		$(cmake-utils_use_enable link LINK)
+		$(cmake-utils_use_enable lirc LIRC)
+		$(cmake-utils_use_enable nls NLS)
+		$(cmake-utils_use_enable openal OPENAL)
+		$(cmake-utils_use_enable sdl SDL)
+		$(cmake-utils_use_enable wxwidgets WX)
+		$(cmake-utils_use_enable x86 ASM_CORE)
+		$(cmake-utils_use_enable x86 ASM_SCALERS)
+		-DCMAKE_INSTALL_PREFIX="${GAMES_PREFIX}"
+		-DCMAKE_SKIP_RPATH=ON
+		-DDATA_INSTALL_DIR=share/games/${PN}
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use sdl ; then
+		dodoc doc/ReadMe.SDL.txt || die
+		doman debian/vbam.1 || die
+	fi
+
+	prepgamesdirs
+}