version bump (bug #414511)

(Portage version: 2.1.10.49/cvs/Linux x86_64)

2 files changed, 88 insertions, 1 deletions

diff --git a/games-board/pokerth/ChangeLog b/games-board/pokerth/ChangeLog
index b1b04ec1984a..a74ee63a155e 100644
--- a/games-board/pokerth/ChangeLog
+++ b/games-board/pokerth/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-board/pokerth
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/pokerth/ChangeLog,v 1.32 2012/03/22 21:30:54 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/pokerth/ChangeLog,v 1.33 2012/05/03 21:01:02 mr_bones_ Exp $
+
+*pokerth-0.9.4 (03 May 2012)
+
+  03 May 2012; Michael Sterrett <mr_bones_@gentoo.org> +pokerth-0.9.4.ebuild:
+  version bump (bug #414511)
 
   22 Mar 2012; Michael Sterrett <mr_bones_@gentoo.org> pokerth-0.9.1.ebuild:
   Add use dep for tinyxml (bug #409377)
diff --git a/games-board/pokerth/pokerth-0.9.4.ebuild b/games-board/pokerth/pokerth-0.9.4.ebuild
new file mode 100644
index 000000000000..bc7de3a4a2a3
--- /dev/null
+++ b/games-board/pokerth/pokerth-0.9.4.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/pokerth/pokerth-0.9.4.ebuild,v 1.1 2012/05/03 21:01:02 mr_bones_ Exp $
+
+EAPI=2
+inherit flag-o-matic eutils qt4-r2 games
+
+MY_P="PokerTH-${PV}-src"
+DESCRIPTION="Texas Hold'em poker game"
+HOMEPAGE="http://www.pokerth.net/"
+SRC_URI="mirror://sourceforge/pokerth/${MY_P}.tar.bz2"
+
+LICENSE="AGPL-3 GPL-1 GPL-2 GPL-3 BitstreamVera public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dedicated"
+
+RDEPEND="dev-db/sqlite:3
+	>=dev-libs/boost-1.44
+	dev-libs/libgcrypt
+	dev-libs/tinyxml[stl]
+	net-libs/libircclient
+	>=net-misc/curl-7.16
+	x11-libs/qt-core:4
+	virtual/gsasl
+	!dedicated? (
+		media-libs/libsdl
+		media-libs/sdl-mixer[mikmod,vorbis]
+		x11-libs/qt-gui:4
+	)"
+DEPEND="${RDEPEND}
+	!dedicated? ( x11-libs/qt-sql:4 )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	if use dedicated ; then
+		sed -i \
+			-e 's/pokerth_game.pro//' \
+			pokerth.pro \
+			|| die "sed failed"
+	fi
+
+	sed -i \
+		-e '/no_dead_strip_inits_and_terms/d' \
+		*pro \
+		|| die 'sed failed'
+
+	local boost_ver=$(best_version ">=dev-libs/boost-1.41")
+
+	boost_ver=${boost_ver/*boost-/}
+	boost_ver=${boost_ver%.*}
+	boost_ver=${boost_ver/./_}
+
+	einfo "Using boost version ${boost_ver}"
+	append-cxxflags \
+		-I/usr/include/boost-${boost_ver}
+	append-ldflags \
+		-L/usr/$(get_libdir)/boost-${boost_ver}
+	append-flags -DBOOST_FILESYSTEM_VERSION=2
+
+	export BOOST_INCLUDEDIR="/usr/include/boost-${boost_ver}"
+	export BOOST_LIBRARYDIR="/usr/$(get_libdir)/boost-${boost_ver}"
+}
+
+src_configure() {
+	eqmake4
+}
+
+src_install() {
+	dogamesbin bin/pokerth_server || die
+	if ! use dedicated ; then
+		dogamesbin ${PN} || die
+		insinto "${GAMES_DATADIR}/${PN}"
+		doins -r data || die
+		domenu ${PN}.desktop
+		doicon ${PN}.png
+	fi
+	doman docs/pokerth.1
+	dodoc ChangeLog TODO docs/{gui_styling,server_setup}_howto.txt
+	prepgamesdirs
+}