Fix installation of man page and add missing deps (bug 432396 by Nikoli). Thanks to Arfrever for some clarifications about distutils.eclass.

(Portage version: 2.2.0_alpha122/cvs/Linux x86_64)

3 files changed, 65 insertions, 49 deletions

diff --git a/dev-vcs/hgview/ChangeLog b/dev-vcs/hgview/ChangeLog
index 1c8c695f311d..bafa55dfac1f 100644
--- a/dev-vcs/hgview/ChangeLog
+++ b/dev-vcs/hgview/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-vcs/hgview
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/ChangeLog,v 1.6 2012/08/23 01:05:34 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/ChangeLog,v 1.7 2012/08/25 10:03:54 pesa Exp $
+
+*hgview-1.6.2-r1 (25 Aug 2012)
+
+  25 Aug 2012; Davide Pesavento <pesa@gentoo.org> +hgview-1.6.2-r1.ebuild,
+  -hgview-1.6.2.ebuild:
+  Fix installation of man page and add missing deps (bug 432396 by Nikoli).
+  Thanks to Arfrever for some clarifications about distutils.eclass.
 
 *hgview-1.6.2 (23 Aug 2012)
 
diff --git a/dev-vcs/hgview/hgview-1.6.2-r1.ebuild b/dev-vcs/hgview/hgview-1.6.2-r1.ebuild
new file mode 100644
index 000000000000..16896a1e94ca
--- /dev/null
+++ b/dev-vcs/hgview/hgview-1.6.2-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/hgview-1.6.2-r1.ebuild,v 1.1 2012/08/25 10:03:54 pesa Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="2:2.5"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.4 3.* *-jython *-pypy-*"
+
+inherit distutils
+
+DESCRIPTION="PyQt4-based Mercurial log navigator"
+HOMEPAGE="http://www.logilab.org/project/hgview"
+SRC_URI="http://ftp.logilab.org/pub/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="dev-python/docutils
+	dev-python/PyQt4[X]
+	dev-python/qscintilla-python
+	dev-vcs/mercurial"
+DEPEND="${RDEPEND}
+	doc? (
+		app-text/asciidoc
+		app-text/xmlto
+	)"
+
+# If this flag is not set, distutils.eclass won't pass
+# any arguments to the "build" action in src_install()
+DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"
+PYTHON_MODNAME="hgext/hgview.py hgviewlib"
+
+src_prepare() {
+	# https://www.logilab.org/ticket/103668
+	sed -i \
+		-e 's:MANDIR=$(PREFIX)/man:MANDIR=$(PREFIX)/share/man:' \
+		-e 's:$(INSTALL) $$i:$(INSTALL) -m 644 $$i:' \
+		doc/Makefile || die
+
+	distutils_src_prepare
+}
+
+src_compile() {
+	distutils_src_compile $(use doc || echo --no-doc)
+}
+
+src_install() {
+	distutils_src_install $(use doc || echo --no-doc)
+
+	# Install Mercurial extension config file
+	insinto /etc/mercurial/hgrc.d
+	doins hgext/hgview.rc
+}
diff --git a/dev-vcs/hgview/hgview-1.6.2.ebuild b/dev-vcs/hgview/hgview-1.6.2.ebuild
deleted file mode 100644
index 8acbece10eba..000000000000
--- a/dev-vcs/hgview/hgview-1.6.2.ebuild
+++ /dev/null
@@ -1,48 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/hgview-1.6.2.ebuild,v 1.1 2012/08/23 01:05:34 pesa Exp $
-
-EAPI=4
-
-PYTHON_DEPEND="2:2.5"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="2.4 3.* *-jython"
-
-inherit distutils
-
-DESCRIPTION="PyQt4-based Mercurial log navigator"
-HOMEPAGE="http://www.logilab.org/project/hgview"
-SRC_URI="http://ftp.logilab.org/pub/${PN}/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc"
-
-DEPEND="dev-python/docutils
-	dev-python/egenix-mx-base
-	dev-python/PyQt4[X]
-	dev-python/qscintilla-python
-	dev-vcs/mercurial
-	doc? ( app-text/asciidoc )"
-RDEPEND="${DEPEND}"
-
-PYTHON_MODNAME="hgext/hgview.py hgviewlib"
-
-src_prepare() {
-	distutils_src_prepare
-
-	# Fix mercurial extension install path.
-	if ! use doc; then
-		sed -e '/make -C doc/d' -i setup.py || die
-		sed -e '/share\/man\/man1/,+1 d' -i hgviewlib/__pkginfo__.py || die
-	fi
-}
-
-src_install() {
-	distutils_src_install
-
-	# Install the mercurial extension config.
-	insinto /etc/mercurial/hgrc.d
-	doins "${FILESDIR}"/hgview.rc
-}