bump

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 68 insertions, 2 deletions

diff --git a/dev-python/mwlib-rl/ChangeLog b/dev-python/mwlib-rl/ChangeLog
index ba0782388303..01de2a188775 100644
--- a/dev-python/mwlib-rl/ChangeLog
+++ b/dev-python/mwlib-rl/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/mwlib-rl
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib-rl/ChangeLog,v 1.3 2013/11/27 21:37:16 dev-zero Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib-rl/ChangeLog,v 1.4 2014/04/12 11:38:28 idella4 Exp $
+
+*mwlib-rl-0.14.5 (12 Apr 2014)
+
+  12 Apr 2014; Ian Delaney <idella4@gentoo.org> +mwlib-rl-0.14.5.ebuild:
+  bump
 
 *mwlib-rl-0.14.4 (27 Nov 2013)
 
diff --git a/dev-python/mwlib-rl/mwlib-rl-0.14.5.ebuild b/dev-python/mwlib-rl/mwlib-rl-0.14.5.ebuild
new file mode 100644
index 000000000000..bbd09be8594b
--- /dev/null
+++ b/dev-python/mwlib-rl/mwlib-rl-0.14.5.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/mwlib-rl/mwlib-rl-0.14.5.ebuild,v 1.1 2014/04/12 11:38:28 idella4 Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+PYTHON_REQ_USE="xml"
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Generate pdfs from mediawiki markup"
+HOMEPAGE="http://code.pediapress.com/wiki/wiki http://pypi.python.org/pypi/mwlib.rl"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test pdftk"
+
+RDEPEND=">=dev-python/mwlib-0.15.8-r1[${PYTHON_USEDEP}]
+	>=dev-python/mwlib-ext-0.12.4-r1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-1.4[${PYTHON_USEDEP}]
+	dev-python/simplejson[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	media-fonts/freefont
+	|| ( media-gfx/graphicsmagick[imagemagick] media-gfx/imagemagick )
+	pdftk? ( app-text/pdftk )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	app-arch/unzip
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=( "${FILESDIR}/0.14.3-use-system-fonts.patch" )
+DOCS=( example-mwlib.config README.rst )
+
+python_prepare_all() {
+	rm -r mwlib/fonts/freefont || die "removing bundled fonts failed"
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test  || die "tests failed under ${EPYTHON}"
+}
+
+pkg_postinst() {
+	elog "If you need extended/non-lating rendering support, please install the"
+	elog "corresponding font packages:"
+	elog " - media-fonts/libertine-ttf"
+	elog " - media-fonts/sil-ezra"
+	elog " - media-fonts/farsi-fonts"
+	elog " - media-fonts/arphicfonts"
+	elog " - media-fonts/unfonts"
+	# TODO: need the following packages as well:
+	# ttf-indic-fonts ttf-gfs-artemisia  ttf-thai-arundina
+}