Migrate to python-r1.

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 9627F456F9DA7643!)

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/subunit/subunit-0.0.10-r1.ebuild b/dev-python/subunit/subunit-0.0.10-r1.ebuild
new file mode 100644
index 000000000000..2c1e3fa71201
--- /dev/null
+++ b/dev-python/subunit/subunit-0.0.10-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/subunit-0.0.10-r1.ebuild,v 1.1 2013/04/19 15:19:28 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_1,3_2,3_3} )
+
+inherit autotools-utils python-r1
+
+DESCRIPTION="A streaming protocol for test results"
+HOMEPAGE="https://launchpad.net/subunit http://pypi.python.org/pypi/python-subunit"
+SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
+
+LICENSE="Apache-2.0 BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=dev-python/testtools-0.9.23[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-libs/check
+	dev-util/cppunit
+	>=sys-devel/automake-1.12
+	virtual/pkgconfig"
+
+src_prepare() {
+	# update py-compile to handle py3 properly
+	# XXX: handle it in the eclass?
+	cp "$(automake --print-libdir || die)"/py-compile . || die
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	python_parallel_foreach_impl autotools-utils_src_configure
+}
+
+src_compile() {
+	python_foreach_impl autotools-utils_src_compile
+}
+
+src_test() {
+	python_parallel_foreach_impl autotools-utils_src_test
+}
+
+src_install() {
+	python_foreach_impl autotools-utils_src_install
+}