bump; rm IUSE doc and related content due to absence of content in acquired tarball, patch to match, tidy to test phase, ebuild adapted from submission in bug #524228 by W. King, closes said bug

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-python/south/south-1.0.ebuild b/dev-python/south/south-1.0.ebuild
new file mode 100644
index 000000000000..53ee97088efc
--- /dev/null
+++ b/dev-python/south/south-1.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/south/south-1.0.ebuild,v 1.1 2014/10/03 05:24:57 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="South"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Intelligent schema migrations for Django apps."
+HOMEPAGE="http://south.aeracode.org/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="<dev-python/django-1.7[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/django[sqlite] )"
+
+PATCHES=( "${FILESDIR}"/${P}-3753b49c-Replace-dict.iteritems-with-six.patch )
+
+S="${WORKDIR}/${MY_P}"
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+	django-admin.py startproject southtest || die "setting up test env failed"
+	pushd southtest > /dev/null
+	sed -i \
+		-e "/^INSTALLED_APPS/a\    'south'," \
+		southtest/settings.py || die "sed failed"
+	echo "SKIP_SOUTH_TESTS=False" >> southtest/settings.py
+	"${EPYTHON}" manage.py test south || die "tests failed for ${EPYTHON}"
+	popd > /dev/null
+}
+
+pkg_postinst() {
+	elog "In order to use the south schema migrations for your Django project,"
+	elog "just add 'south' to your INSTALLED_APPS in the settings.py file."
+	elog "manage.py will now automagically offer the new functions."
+}