Version bump pyudev to 0.12.

(Portage version: 2.1.10.15/cvs/Linux x86_64)

2 files changed, 62 insertions, 1 deletions

diff --git a/dev-python/pyudev/ChangeLog b/dev-python/pyudev/ChangeLog
index ff7864b6596c..4c44bf495f2e 100644
--- a/dev-python/pyudev/ChangeLog
+++ b/dev-python/pyudev/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyudev
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyudev/ChangeLog,v 1.7 2011/08/05 22:27:53 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyudev/ChangeLog,v 1.8 2011/09/13 08:00:09 djc Exp $
+
+*pyudev-0.12 (13 Sep 2011)
+
+  13 Sep 2011; Dirkjan Ochtman <djc@gentoo.org> +pyudev-0.12.ebuild:
+  Version bump to 0.12.
 
   05 Aug 2011; Markos Chandras <hwoarang@gentoo.org> -pyudev-0.10.ebuild:
   Remove old ebuild. Requested by Arfrever
diff --git a/dev-python/pyudev/pyudev-0.12.ebuild b/dev-python/pyudev/pyudev-0.12.ebuild
new file mode 100644
index 000000000000..fda7c4e948c7
--- /dev/null
+++ b/dev-python/pyudev/pyudev-0.12.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyudev/pyudev-0.12.ebuild,v 1.1 2011/09/13 08:00:09 djc Exp $
+
+EAPI="3"
+PYTHON_DEPEND="*:2.6"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.[45] *-jython"
+DISTUTILS_SRC_TEST="py.test"
+
+inherit distutils
+
+DESCRIPTION="Python binding to libudev"
+HOMEPAGE="http://packages.python.org/pyudev/ http://pypi.python.org/pypi/pyudev"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="pygobject pyqt4 pyside"
+
+RDEPEND=">=sys-fs/udev-151
+	pygobject? ( dev-python/pygobject )
+	pyqt4? ( dev-python/PyQt4 )
+	pyside? ( dev-python/pyside )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools
+	test? ( dev-python/mock )"
+
+DOCS="CHANGES.rst README.rst"
+
+src_prepare() {
+	distutils_src_prepare
+
+	# fix run_path
+	sed -i -e "s|/run/udev|/dev/.udev|g" tests/test_core.py
+
+	if ! use pygobject; then
+		rm -f pyudev/glib.py
+		sed -i -e "s|[, ]*GlibBinding()||g" tests/test_observer.py
+	fi
+	if ! use pyqt4; then
+		rm -f pyudev/pyqt4.py
+		sed -i -e "s|Qt4Binding('PyQt4')[, ]*||g" tests/test_observer.py
+	fi
+	if ! use pyside; then
+		rm -f pyudev/pyside.py
+		sed -i -e "s|Qt4Binding('PySide')[, ]*||g" tests/test_observer.py
+	fi
+	if ! use pyqt4 && ! use pyside; then
+		rm -f pyudev/_qt_base.py
+	fi
+	if ! use pyqt4 && ! use pyside && ! use pygobject; then
+		rm -f tests/test_observer.py
+	fi
+}