Version bump, drop old

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-python/python-slip/python-slip-0.6.1.ebuild b/dev-python/python-slip/python-slip-0.6.1.ebuild
new file mode 100644
index 000000000000..db988994eff3
--- /dev/null
+++ b/dev-python/python-slip/python-slip-0.6.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-slip/python-slip-0.6.1.ebuild,v 1.1 2015/06/07 10:34:33 pacho Exp $
+
+EAPI=5
+
+PYTHON_REQ_USE="xml"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Miscellaneous convenience, extension and workaround code for Python"
+HOMEPAGE="https://fedorahosted.org/python-slip/"
+SRC_URI="https://fedorahosted.org/released/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dbus selinux"
+
+RDEPEND="
+	dbus? (
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		sys-auth/polkit )
+"
+DEPEND=""
+
+python_prepare_all() {
+	use selinux || epatch "${FILESDIR}/${PN}-0.4.0-no-selinux.patch"
+
+	# hard-disable slip.gtk since it did not get ported to gtk3+ and the only user
+	# of slip (firewalld) does not use it (upstream disables it for py3 already)
+	sed \
+		-e 's|sys.version_info.major == 2|False|' \
+		-e "s:@VERSION@:${PV}:" setup.py.in > setup.py || die "sed failed"
+
+	if ! use dbus; then
+		sed -e '/name="slip.dbus"/ s/\(.*\)/if 0:\n    \1/' \
+			-i setup.py || die "sed 2 failed"
+	fi
+
+	distutils-r1_python_prepare_all
+}