Version bump, add examples use flag.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 62 insertions, 1 deletions

diff --git a/dev-python/pyopenssl/ChangeLog b/dev-python/pyopenssl/ChangeLog
index 0f86acb7314b..eb35b032e42f 100644
--- a/dev-python/pyopenssl/ChangeLog
+++ b/dev-python/pyopenssl/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyopenssl
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyopenssl/ChangeLog,v 1.113 2014/02/10 03:20:00 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyopenssl/ChangeLog,v 1.114 2014/03/01 05:56:41 radhermit Exp $
+
+*pyopenssl-0.14 (01 Mar 2014)
+
+  01 Mar 2014; Tim Harder <radhermit@gentoo.org> +pyopenssl-0.14.ebuild:
+  Version bump, add examples use flag.
 
   10 Feb 2014; Mike Frysinger <vapier@gentoo.org> pyopenssl-0.13.1-r1.ebuild,
   pyopenssl-0.13.1.ebuild:
diff --git a/dev-python/pyopenssl/pyopenssl-0.14.ebuild b/dev-python/pyopenssl/pyopenssl-0.14.ebuild
new file mode 100644
index 000000000000..d3812d432a4f
--- /dev/null
+++ b/dev-python/pyopenssl/pyopenssl-0.14.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyopenssl/pyopenssl-0.14.ebuild,v 1.1 2014/03/01 05:56:41 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=pyOpenSSL
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python interface to the OpenSSL library"
+HOMEPAGE="http://pyopenssl.sourceforge.net/ https://launchpad.net/pyopenssl http://pypi.python.org/pypi/pyOpenSSL"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+
+RDEPEND=">=dev-python/six-1.5.2[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-0.2.1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+	sed \
+		-e "s/test_set_tlsext_host_name_wrong_args/_&/" \
+		-i OpenSSL/test/test_ssl.py || die "test_ssl sed failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	esetup.py test
+
+	# https://bugs.launchpad.net/pyopenssl/+bug/1237953
+	rm -rf tmp* *.key *.pem
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}