bump; add py3.4, drop pypy2_0 support

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 66 insertions, 1 deletions

diff --git a/dev-python/py-amqp/ChangeLog b/dev-python/py-amqp/ChangeLog
index 6c2a04535fed..bfe12aa4e90f 100644
--- a/dev-python/py-amqp/ChangeLog
+++ b/dev-python/py-amqp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/py-amqp
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/ChangeLog,v 1.20 2014/03/31 20:53:20 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/ChangeLog,v 1.21 2014/04/27 07:04:31 idella4 Exp $
+
+*py-amqp-1.4.5 (27 Apr 2014)
+
+  27 Apr 2014; Ian Delaney <idella4@gentoo.org> +py-amqp-1.4.5.ebuild:
+  bump; add py3.4, drop pypy2_0 support
 
   31 Mar 2014; Michał Górny <mgorny@gentoo.org> py-amqp-1.0.13.ebuild,
   py-amqp-1.2.1.ebuild, py-amqp-1.3.3-r1.ebuild, py-amqp-1.4.2.ebuild,
diff --git a/dev-python/py-amqp/py-amqp-1.4.5.ebuild b/dev-python/py-amqp/py-amqp-1.4.5.ebuild
new file mode 100644
index 000000000000..c3a8b6015e59
--- /dev/null
+++ b/dev-python/py-amqp/py-amqp-1.4.5.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/py-amqp/py-amqp-1.4.5.ebuild,v 1.1 2014/04/27 07:04:31 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="amqp"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Low-level AMQP client for Python (fork of amqplib)"
+HOMEPAGE="https://github.com/celery/py-amqp http://pypi.python.org/pypi/amqp/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples extras test"
+
+RDEPEND=""
+DEPEND="test? ( virtual/python-unittest2[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/nose-cover3[${PYTHON_USEDEP}]
+		>=dev-python/coverage-3.0[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/sphinxcontrib-issuetracker-0.9[${PYTHON_USEDEP}] )"
+
+# Same tests from before require a socket connection
+PATCHES=( "${FILESDIR}"/${PN}-1.3.3-disable_socket_tests.patch )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	cp -r -l funtests "${BUILD_DIR}"/lib/ || die
+	cd "${BUILD_DIR}"/lib || die
+	if [[ ${EPYTHON:6:1} == 3 ]]; then
+		#   -n causes Python to write into hardlinked files
+		2to3 --no-diffs -w funtests || die
+	fi
+	"${PYTHON}" funtests/run_all.py || die "Tests failed under ${EPYTHON}"
+	rm -rf funtests/ || die
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( demo/. )
+	use doc && local HTML_DOCS=( docs/.build/html/. )
+	if use extras; then
+		insinto /usr/share/${PF}/extras
+		doins -r extra
+	fi
+	distutils-r1_python_install_all
+}