Initial import

(Portage version: 2.1.10.10/cvs/Linux x86_64)

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-python/envisage/envisage-4.0.0.ebuild b/dev-python/envisage/envisage-4.0.0.ebuild
new file mode 100644
index 000000000000..19b8a740df65
--- /dev/null
+++ b/dev-python/envisage/envisage-4.0.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/envisage/envisage-4.0.0.ebuild,v 1.1 2011/08/03 23:47:33 bicatali Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.* *-jython"
+DISTUTILS_SRC_TEST="nosetests"
+
+inherit distutils virtualx
+
+DESCRIPTION="Enthought Tool Suite: extensible application framework"
+HOMEPAGE="http://code.enthought.com/projects/envisage/ http://pypi.python.org/pypi/envisage"
+SRC_URI="http://www.enthought.com/repo/ets/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/traits-4.0"
+DEPEND="dev-python/setuptools
+	doc? ( dev-python/sphinx )
+	test? (
+		>=dev-python/traits-4.0
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+	)"
+
+src_compile() {
+	distutils_src_compile
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null
+		emake html || die "Generation of documentation failed"
+		popd > /dev/null
+	fi
+}
+
+src_test() {
+	VIRTUALX_COMMAND="distutils_src_test" virtualmake
+}
+
+src_install() {
+	distutils_src_install
+
+	if use doc; then
+		pushd docs/build/html > /dev/null
+		insinto /usr/share/doc/${PF}/html
+		doins -r [a-z]* _static || die "Installation of documentation failed"
+		popd > /dev/null
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r examples/* || die "Installation of examples failed"
+	fi
+}