Update ebuild for python-r1.eclass in preparation for stabilization. Skip another failing test (fixed in 2.36).

(Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

3 files changed, 314 insertions, 1 deletions

diff --git a/dev-libs/glib/ChangeLog b/dev-libs/glib/ChangeLog
index 1c63d6dc9e33..763c2cb9dc96 100644
--- a/dev-libs/glib/ChangeLog
+++ b/dev-libs/glib/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.570 2013/08/15 01:24:32 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.571 2013/08/15 13:01:15 tetromino Exp $
+
+*glib-2.34.3-r1 (15 Aug 2013)
+
+  15 Aug 2013; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +glib-2.34.3-r1.ebuild,
+  +files/glib-2.34.3-testsuite-skip-gdbus-auth-tests.patch:
+  Update ebuild for python-r1.eclass in preparation for stabilization. Skip
+  another failing test (fixed in 2.36).
 
   15 Aug 2013; Alexandre Rostovtsev <tetromino@gentoo.org>
   glib-2.36.3-r2.ebuild:
diff --git a/dev-libs/glib/files/glib-2.34.3-testsuite-skip-gdbus-auth-tests.patch b/dev-libs/glib/files/glib-2.34.3-testsuite-skip-gdbus-auth-tests.patch
new file mode 100644
index 000000000000..c7c3f3364f4f
--- /dev/null
+++ b/dev-libs/glib/files/glib-2.34.3-testsuite-skip-gdbus-auth-tests.patch
@@ -0,0 +1,62 @@
+From 86bc94d3783ba53a944451f4eba4c78130eeef3b Mon Sep 17 00:00:00 2001
+From: Priit Laes <plaes@plaes.org>
+Date: Tue, 3 Jul 2012 12:50:44 +0300
+Subject: [PATCH] Gentoo: skip over gdbus-auth /gdbus/auth/*/DBUS_COOKIE_SHA1
+ tests
+
+https://bugzilla.gnome.org/show_bug.cgi?id=679308
+---
+ gio/tests/gdbus-auth.c | 9 +++++++++
+ 1 file changed, 9 insertions(+)
+
+diff --git a/gio/tests/gdbus-auth.c b/gio/tests/gdbus-auth.c
+index 737770e..d528c6b 100644
+--- a/gio/tests/gdbus-auth.c
++++ b/gio/tests/gdbus-auth.c
+@@ -89,11 +89,14 @@ auth_client_external (void)
+   auth_client_mechanism ("EXTERNAL");
+ }
+ 
++#if 0
++// https://bugzilla.gnome.org/show_bug.cgi?id=679308
+ static void
+ auth_client_dbus_cookie_sha1 (void)
+ {
+   auth_client_mechanism ("DBUS_COOKIE_SHA1");
+ }
++#endif
+ 
+ /* ---------------------------------------------------------------------------------------------------- */
+ 
+@@ -250,11 +253,13 @@ auth_server_external (void)
+   auth_server_mechanism ("EXTERNAL");
+ }
+ 
++#if 0
+ static void
+ auth_server_dbus_cookie_sha1 (void)
+ {
+   auth_server_mechanism ("DBUS_COOKIE_SHA1");
+ }
++#endif
+ 
+ /* ---------------------------------------------------------------------------------------------------- */
+ 
+@@ -272,10 +277,14 @@ main (int   argc,
+   session_bus_up ();
+ 
+   g_test_add_func ("/gdbus/auth/client/EXTERNAL",         auth_client_external);
++#if 0
+   g_test_add_func ("/gdbus/auth/client/DBUS_COOKIE_SHA1", auth_client_dbus_cookie_sha1);
++#endif
+   g_test_add_func ("/gdbus/auth/server/ANONYMOUS",        auth_server_anonymous);
++#if 0
+   g_test_add_func ("/gdbus/auth/server/EXTERNAL",         auth_server_external);
+   g_test_add_func ("/gdbus/auth/server/DBUS_COOKIE_SHA1", auth_server_dbus_cookie_sha1);
++#endif
+ 
+   ret = g_test_run();
+ 
+-- 
+1.8.3.2
+
diff --git a/dev-libs/glib/glib-2.34.3-r1.ebuild b/dev-libs/glib/glib-2.34.3-r1.ebuild
new file mode 100644
index 000000000000..b0071af3f19a
--- /dev/null
+++ b/dev-libs/glib/glib-2.34.3-r1.ebuild
@@ -0,0 +1,243 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.34.3-r1.ebuild,v 1.1 2013/08/15 13:01:15 tetromino Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python2_{5,6,7} )
+# Avoid runtime dependency on python when USE=test
+
+inherit autotools bash-completion-r1 gnome.org libtool eutils flag-o-matic gnome2-utils multilib pax-utils python toolchain-funcs versionator virtualx linux-info
+
+DESCRIPTION="The GLib library of C routines"
+HOMEPAGE="http://www.gtk.org/"
+SRC_URI="${SRC_URI}
+	http://pkgconfig.freedesktop.org/releases/pkg-config-0.28.tar.gz" # pkg.m4 for eautoreconf
+
+LICENSE="LGPL-2+"
+SLOT="2"
+IUSE="debug fam kernel_linux selinux static-libs systemtap test utils xattr"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+
+RDEPEND="virtual/libiconv
+	virtual/libffi
+	sys-libs/zlib
+	|| (
+		>=dev-libs/elfutils-0.142
+		>=dev-libs/libelf-0.8.12
+		>=sys-freebsd/freebsd-lib-9.2_rc1
+		)
+	selinux? ( sys-libs/libselinux )
+	xattr? ( sys-apps/attr )
+	fam? ( virtual/fam )
+	utils? (
+		${PYTHON_DEPS}
+		>=dev-util/gdbus-codegen-${PV}
+	)
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	>=dev-libs/libxslt-1.0
+	>=sys-devel/gettext-0.11
+	>=dev-util/gtk-doc-am-1.15
+	systemtap? ( >=dev-util/systemtap-1.3 )
+	test? (
+		sys-devel/gdb
+		${PYTHON_DEPS}
+		>=dev-util/gdbus-codegen-${PV}
+		>=sys-apps/dbus-1.2.14 )
+	!<dev-libs/gobject-introspection-1.$(get_version_component_range 2)
+	!<dev-util/gtk-doc-1.15-r2
+"
+# gobject-introspection blocker to ensure people don't mix
+# different g-i and glib major versions
+
+PDEPEND="x11-misc/shared-mime-info
+	!<gnome-base/gvfs-1.6.4-r990"
+# shared-mime-info needed for gio/xdgmime, bug #409481
+# Earlier versions of gvfs do not work with glib
+
+pkg_setup() {
+	if use kernel_linux ; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		linux-info_pkg_setup
+	fi
+}
+
+src_prepare() {
+	# Prevent build failure in stage3 where pkgconfig is not available, bug #481056
+	mv -f "${WORKDIR}"/pkg-config-*/pkg.m4 "${S}"/m4macros/ || die
+
+	# Fix gmodule issues on fbsd; bug #184301, upstream bug #107626
+	epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch
+
+	if use test; then
+		# Do not try to remove files on live filesystem, upstream bug #619274
+		sed 's:^\(.*"/desktop-app-info/delete".*\):/*\1*/:' \
+			-i "${S}"/gio/tests/desktop-app-info.c || die "sed failed"
+
+		# Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629, upstream bug #629163
+		if ! has_version dev-util/desktop-file-utils ; then
+			ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
+			ewarn "think on installing it to get these tests run."
+			sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
+			sed -i -e "/desktop-app-info\/default/d" gio/tests/desktop-app-info.c || die
+			sed -i -e "/desktop-app-info\/fallback/d" gio/tests/desktop-app-info.c || die
+			sed -i -e "/desktop-app-info\/lastused/d" gio/tests/desktop-app-info.c || die
+		fi
+
+		# Disable tests requiring dbus-python and pygobject; bugs #349236, #377549, #384853
+		if ! has_version dev-python/dbus-python || ! has_version 'dev-python/pygobject:3' ; then
+			ewarn "Some tests will be skipped due to dev-python/dbus-python or dev-python/pygobject:3"
+			ewarn "not being present on your system, think on installing them to get these tests run."
+			sed -i -e "/connection\/filter/d" gio/tests/gdbus-connection.c || die
+			sed -i -e "/connection\/large_message/d" gio/tests/gdbus-connection-slow.c || die
+			sed -i -e "/gdbus\/proxy/d" gio/tests/gdbus-proxy.c || die
+			sed -i -e "/gdbus\/proxy-well-known-name/d" gio/tests/gdbus-proxy-well-known-name.c || die
+			sed -i -e "/gdbus\/introspection-parser/d" gio/tests/gdbus-introspection.c || die
+			sed -i -e "/g_test_add_func/d" gio/tests/gdbus-threading.c || die
+			sed -i -e "/gdbus\/method-calls-in-thread/d" gio/tests/gdbus-threading.c || die
+			# needed to prevent gdbus-threading from asserting
+			ln -sfn $(type -P true) gio/tests/gdbus-testserver.py
+		fi
+	fi
+
+	# gdbus-codegen is a separate package
+	epatch "${FILESDIR}/${PN}-2.31.x-external-gdbus-codegen.patch"
+
+	# leave python shebang alone
+	sed -e '/${PYTHON}/d' \
+		-i glib/Makefile.{am,in} || die
+
+	# Gentoo handles completions in a different directory
+	sed -i "s|^completiondir =.*|completiondir = $(get_bashcompdir)|" \
+		gio/Makefile.am || die
+
+	# https://bugzilla.gnome.org/show_bug.cgi?id=679306
+	epatch "${FILESDIR}/${PN}-2.34.0-testsuite-skip-thread4.patch"
+	# https://bugzilla.gnome.org/show_bug.cgi?id=679308
+	epatch "${FILESDIR}/${PN}-2.34.3-testsuite-skip-gdbus-auth-tests.patch"
+
+	# build failure with automake-1.13; fixed upstream in 2.36
+	epatch "${FILESDIR}/${PN}-2.34.3-automake-1.13.patch"
+
+	epatch_user
+
+	# Needed for the punt-python-check patch, disabling timeout test
+	# Also needed to prevent croscompile failures, see bug #267603
+	# Also needed for the no-gdbus-codegen patch
+	eautoreconf
+
+	[[ ${CHOST} == *-freebsd* ]] && elibtoolize
+
+	epunt_cxx
+}
+
+src_configure() {
+	# Avoid circular depend with dev-util/pkgconfig and
+	# native builds (cross-compiles won't need pkg-config
+	# in the target ROOT to work here)
+	if ! tc-is-cross-compiler && ! $(tc-getPKG_CONFIG) --version >& /dev/null; then
+		if has_version sys-apps/dbus; then
+			export DBUS1_CFLAGS="-I/usr/include/dbus-1.0 -I/usr/$(get_libdir)/dbus-1.0/include"
+			export DBUS1_LIBS="-ldbus-1"
+		fi
+		export LIBFFI_CFLAGS="-I$(echo /usr/$(get_libdir)/libffi-*/include)"
+		export LIBFFI_LIBS="-lffi"
+	fi
+
+	local myconf
+
+	# Building with --disable-debug highly unrecommended.  It will build glib in
+	# an unusable form as it disables some commonly used API.  Please do not
+	# convert this to the use_enable form, as it results in a broken build.
+	use debug && myconf="--enable-debug"
+
+	if use test; then
+		myconf="${myconf} --enable-modular-tests"
+	else
+		if [[ ${PV} = 9999 ]] && use doc; then
+			# need to build tests if USE=doc for bug #387385
+			myconf="${myconf} --enable-modular-tests"
+		else
+			myconf="${myconf} --disable-modular-tests"
+		fi
+	fi
+
+	# Always use internal libpcre, bug #254659
+	econf ${myconf} \
+		$(use_enable xattr) \
+		$(use_enable fam) \
+		$(use_enable selinux) \
+		$(use_enable static-libs static) \
+		$(use_enable systemtap dtrace) \
+		$(use_enable systemtap systemtap) \
+		--enable-man \
+		--with-pcre=internal \
+		--with-threads=posix \
+		--with-xml-catalog="${EPREFIX}/etc/xml/catalog"
+}
+
+src_install() {
+	default
+
+	if use utils ; then
+		python_replicate_script "${ED}"/usr/bin/gtester-report
+	else
+		rm "${ED}usr/bin/gtester-report"
+		rm "${ED}usr/share/man/man1/gtester-report.1"
+	fi
+
+	# Do not install charset.alias even if generated, leave it to libiconv
+	rm -f "${ED}/usr/lib/charset.alias"
+
+	# Don't install gdb python macros, bug 291328
+	rm -rf "${ED}/usr/share/gdb/" "${ED}/usr/share/glib-2.0/gdb/"
+
+	dodoc AUTHORS ChangeLog* NEWS* README
+
+	# Completely useless with or without USE static-libs, people need to use
+	# pkg-config
+	prune_libtool_files --modules
+}
+
+src_test() {
+	gnome2_environment_reset
+
+	unset DBUS_SESSION_BUS_ADDRESS
+	export XDG_CONFIG_DIRS=/etc/xdg
+	export XDG_DATA_DIRS=/usr/local/share:/usr/share
+	export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
+	unset GSETTINGS_BACKEND # bug 352451
+	export LC_TIME=C # bug #411967
+	python_export_best
+
+	# Related test is a bit nitpicking
+	mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+	chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+
+	# Hardened: gdb needs this, bug #338891
+	if host-is-pax ; then
+		pax-mark -mr "${S}"/tests/.libs/assert-msg-test \
+			|| die "Hardened adjustment failed"
+	fi
+
+	# Need X for dbus-launch session X11 initialization
+	Xemake check
+}
+
+pkg_postinst() {
+	# Inform users about possible breakage when updating glib and not dbus-glib, bug #297483
+	# TODO: add a subslotted virtual to trigger this automatically
+	if has_version dev-libs/dbus-glib; then
+		ewarn "If you experience a breakage after updating dev-libs/glib try"
+		ewarn "rebuilding dev-libs/dbus-glib"
+	fi
+
+	if has_version '<x11-libs/gtk+-3.0.12:3'; then
+		# To have a clear upgrade path for gtk+-3.0.x users, have to resort to
+		# a warning instead of a blocker
+		ewarn
+		ewarn "Using <gtk+-3.0.12:3 with ${P} results in frequent crashes."
+		ewarn "You should upgrade to a newer version of gtk+:3 immediately."
+	fi
+}