Fix tcl/tk slotting; bump to EAPI=5

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

3 files changed, 147 insertions, 11 deletions

diff --git a/dev-lang/mozart/ChangeLog b/dev-lang/mozart/ChangeLog
index 32f78104bce4..ae85df8f7faf 100644
--- a/dev-lang/mozart/ChangeLog
+++ b/dev-lang/mozart/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lang/mozart
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mozart/ChangeLog,v 1.40 2012/08/27 08:05:52 keri Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mozart/ChangeLog,v 1.41 2015/03/25 12:27:23 jlec Exp $
+
+*mozart-1.4.0-r3 (25 Mar 2015)
+
+  25 Mar 2015; Justin Lecher <jlec@gentoo.org> +mozart-1.4.0-r3.ebuild,
+  mozart-1.4.0-r2.ebuild:
+  Fix tcl/tk slotting; bump to EAPI=5
 
   27 Aug 2012; <keri@gentoo.org> -files/mozart-1.3.2-const-cast.patch,
   -files/mozart-1.3.2-contrib.patch, -files/mozart-1.3.2-emubin.patch,
diff --git a/dev-lang/mozart/mozart-1.4.0-r2.ebuild b/dev-lang/mozart/mozart-1.4.0-r2.ebuild
index c6c2fb4cbf06..94e81478368d 100644
--- a/dev-lang/mozart/mozart-1.4.0-r2.ebuild
+++ b/dev-lang/mozart/mozart-1.4.0-r2.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mozart/mozart-1.4.0-r2.ebuild,v 1.6 2012/08/22 10:42:47 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mozart/mozart-1.4.0-r2.ebuild,v 1.7 2015/03/25 12:27:23 jlec Exp $
 
 EAPI="2"
 
@@ -9,25 +9,30 @@ inherit elisp-common eutils
 PATCHSET_VER="5"
 MY_P="mozart-${PV}.20080704"
 
-DESCRIPTION="Mozart is an advanced development platform for intelligent, distributed applications"
+DESCRIPTION="Advanced development platform for intelligent, distributed applications"
 HOMEPAGE="http://www.mozart-oz.org/"
-SRC_URI="http://www.mozart-oz.org/download/mozart-ftp/store/1.4.0-2008-07-02-tar/mozart-1.4.0.20080704-src.tar.gz
+SRC_URI="
+	http://www.mozart-oz.org/download/mozart-ftp/store/1.4.0-2008-07-02-tar/mozart-1.4.0.20080704-src.tar.gz
 	mirror://gentoo/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz
 	doc? ( http://www.mozart-oz.org/download/mozart-ftp/store/1.4.0-2008-07-02-tar/mozart-1.4.0.20080704-doc.tar.gz )"
-LICENSE="Mozart"
 
 SLOT="0"
+LICENSE="Mozart"
 KEYWORDS="-amd64 ppc -ppc64 x86"
 IUSE="doc emacs examples gdbm static tcl threads tk"
 
-RDEPEND="dev-lang/perl
+RDEPEND="
+	dev-lang/perl
 	dev-libs/gmp
 	sys-libs/zlib
 	emacs? ( virtual/emacs )
 	gdbm? ( sys-libs/gdbm  )
-	tcl? ( tk? (
-			dev-lang/tk
-			dev-lang/tcl ) )"
+	tcl? (
+		tk? (
+			dev-lang/tk:0
+			dev-lang/tcl:0
+		)
+	)"
 DEPEND="${RDEPEND}
 	sys-devel/bison
 	sys-devel/flex"
diff --git a/dev-lang/mozart/mozart-1.4.0-r3.ebuild b/dev-lang/mozart/mozart-1.4.0-r3.ebuild
new file mode 100644
index 000000000000..07f36d136316
--- /dev/null
+++ b/dev-lang/mozart/mozart-1.4.0-r3.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mozart/mozart-1.4.0-r3.ebuild,v 1.1 2015/03/25 12:27:23 jlec Exp $
+
+EAPI=5
+
+inherit elisp-common eutils
+
+PATCHSET_VER="5"
+MY_P="mozart-${PV}.20080704"
+
+DESCRIPTION="Advanced development platform for intelligent, distributed applications"
+HOMEPAGE="http://www.mozart-oz.org/"
+SRC_URI="
+	http://www.mozart-oz.org/download/mozart-ftp/store/1.4.0-2008-07-02-tar/mozart-1.4.0.20080704-src.tar.gz
+	mirror://gentoo/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz
+	doc? ( http://www.mozart-oz.org/download/mozart-ftp/store/1.4.0-2008-07-02-tar/mozart-1.4.0.20080704-doc.tar.gz )"
+
+SLOT="0"
+LICENSE="Mozart"
+KEYWORDS="-amd64 ~ppc -ppc64 ~x86"
+IUSE="doc emacs examples gdbm static tcl threads tk"
+
+RDEPEND="
+	dev-lang/perl
+	dev-libs/gmp
+	sys-libs/zlib
+	emacs? ( virtual/emacs )
+	gdbm? ( sys-libs/gdbm  )
+	tcl? (
+		tk? (
+			dev-lang/tk:0=
+			dev-lang/tcl:0=
+		)
+	)"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex"
+
+SITEFILE=50${PN}-gentoo.el
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	epatch "${WORKDIR}"/${PV}
+}
+
+src_configure() {
+	local myconf="\
+			--without-global-oz \
+			--enable-opt=none"
+
+	if use tcl && use tk ; then
+		myconf="${myconf} --enable-wish"
+	else
+		myconf="${myconf} --disable-wish"
+	fi
+
+	econf \
+		${myconf} \
+		--disable-doc \
+		--enable-contrib \
+		--disable-contrib-micq \
+		$(use_enable doc contrib-doc) \
+		$(use_enable gdbm contrib-gdbm) \
+		$(use_enable tk contrib-tk) \
+		$(use_enable emacs compile-elisp) \
+		$(use_enable static link-static) \
+		$(use_enable threads threaded)
+}
+
+src_compile() {
+	emake bootstrap
+}
+
+src_test() {
+	# Mozart tests must be run single-threaded
+	cd "${S}"/share/test || die
+	emake -j1 boot-oztest
+	emake -j1 boot-check
+}
+
+src_install() {
+	emake \
+		PREFIX="${D}"/usr/lib/mozart \
+		ELISPDIR="${D}${SITELISP}/${PN}" \
+		install
+
+	dosym /usr/lib/mozart/bin/convertTextPickle /usr/bin/convertTextPickle
+	dosym /usr/lib/mozart/bin/oldpickle2text /usr/bin/oldpickle2text
+	dosym /usr/lib/mozart/bin/ozc /usr/bin/ozc
+	dosym /usr/lib/mozart/bin/ozd /usr/bin/ozd
+	dosym /usr/lib/mozart/bin/ozengine /usr/bin/ozengine
+	dosym /usr/lib/mozart/bin/ozl /usr/bin/ozl
+	dosym /usr/lib/mozart/bin/ozplatform /usr/bin/ozplatform
+	dosym /usr/lib/mozart/bin/oztool /usr/bin/oztool
+	dosym /usr/lib/mozart/bin/pickle2text /usr/bin/pickle2text
+	dosym /usr/lib/mozart/bin/text2pickle /usr/bin/text2pickle
+
+	if use emacs; then
+		dosym /usr/lib/mozart/bin/oz /usr/bin/oz
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+
+	dodoc "${S}"/README
+	use doc && dohtml -r "${WORKDIR}"/mozart/doc/*
+
+	if use examples; then
+		cd "${S}"/share || die
+		insinto /usr/share/doc/${PF}
+		doins -r examples demo
+		rm -rf $(find "${ED}"/usr/share/doc/${PF}/examples \
+			-name Makefile -o -name Makefile.in) || die
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}