new upstream release.

(Portage version: 2.1.3.19)

2 files changed, 118 insertions, 2 deletions

diff --git a/app-text/hyperestraier/ChangeLog b/app-text/hyperestraier/ChangeLog
index 5daad0eb6fec..27e7b16f9fcb 100644
--- a/app-text/hyperestraier/ChangeLog
+++ b/app-text/hyperestraier/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/hyperestraier
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/hyperestraier/ChangeLog,v 1.46 2007/11/17 20:53:28 wltjr Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/hyperestraier/ChangeLog,v 1.47 2008/02/04 17:28:35 hattya Exp $
+
+*hyperestraier-1.4.13 (04 Feb 2008)
+
+  04 Feb 2008; Akinori Hattori <hattya@gentoo.org>
+  +hyperestraier-1.4.13.ebuild:
+  new upstream release.
 
   17 Nov 2007; William L. Thomson Jr. <wltjr@gentoo.org>
   -hyperestraier-1.4.0-r1.ebuild, -hyperestraier-1.4.9.ebuild,
diff --git a/app-text/hyperestraier/hyperestraier-1.4.13.ebuild b/app-text/hyperestraier/hyperestraier-1.4.13.ebuild
new file mode 100644
index 000000000000..10f13fcafa74
--- /dev/null
+++ b/app-text/hyperestraier/hyperestraier-1.4.13.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/hyperestraier/hyperestraier-1.4.13.ebuild,v 1.1 2008/02/04 17:28:35 hattya Exp $
+
+inherit java-pkg-opt-2
+
+IUSE="debug java mecab ruby"
+
+DESCRIPTION="a full-text search system for communities"
+HOMEPAGE="http://hyperestraier.sf.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+SLOT="0"
+
+RDEPEND=">=dev-db/qdbm-1.8.75
+	sys-libs/zlib
+	java? ( >=virtual/jre-1.4 )
+	mecab? ( app-text/mecab )
+	ruby? ( dev-lang/ruby )"
+DEPEND="${RDEPEND}
+	java? ( >=virtual/jdk-1.4 )"
+
+src_unpack() {
+
+	unpack ${A}
+	cd "${S}"
+
+	# fix for insecure runpath warning.
+	sed -i "/^LDENV/d" Makefile.in
+
+	sed -i "/^JAVACFLAGS/s:$: ${JAVACFLAGS}:" java*/Makefile.in
+
+}
+
+src_compile() {
+
+	econf \
+		`use_enable debug` \
+		`use_enable mecab` \
+		|| die
+	emake || die
+
+	local u d
+
+	for u in java ruby; do
+		if ! use ${u}; then
+			continue
+		fi
+
+		for d in ${u}native ${u}pure; do
+			cd ${d}
+			econf || die
+			emake || die
+			cd -
+		done
+	done
+
+}
+
+src_test() {
+
+	emake -j1 check || die
+
+	local u d
+
+	for u in java ruby; do
+		if ! use ${u}; then
+			continue
+		fi
+
+		for d in ${u}native; do
+			cd ${d}
+			emake -j1 check || die
+			cd -
+		done
+	done
+
+}
+
+src_install() {
+
+	emake DESTDIR="${D}" MYDOCS= install || die
+	dodoc ChangeLog README* THANKS
+	dohtml doc/*
+
+	local u d
+
+	for u in java ruby; do
+		if ! use ${u}; then
+			continue
+		fi
+
+		for d in ${u}native ${u}pure; do
+			cd ${d}
+			emake DESTDIR="${D}" install || die
+			cd -
+			dohtml -r doc/${d}api
+		done
+	done
+
+	if use java; then
+		java-pkg_dojar "${D}"/usr/$(get_libdir)/*.jar
+		rm -f "${D}"/usr/$(get_libdir)/*.jar
+	fi
+
+	rm -f "${D}"/usr/bin/*test
+
+}