version bump (bug #276721)

(Portage version: 2.2_rc42/cvs/Linux i686)

2 files changed, 79 insertions, 1 deletions

diff --git a/app-laptop/laptop-mode-tools/ChangeLog b/app-laptop/laptop-mode-tools/ChangeLog
index 4544418eeddc..baeb17b13bb0 100644
--- a/app-laptop/laptop-mode-tools/ChangeLog
+++ b/app-laptop/laptop-mode-tools/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-laptop/laptop-mode-tools
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog,v 1.44 2009/10/16 18:14:57 bangert Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog,v 1.45 2009/10/16 18:42:23 bangert Exp $
+
+*laptop-mode-tools-1.52 (16 Oct 2009)
+
+  16 Oct 2009; Thilo Bangert <bangert@gentoo.org>
+  +laptop-mode-tools-1.52.ebuild:
+  version bump (bug #276721)
 
   16 Oct 2009; Thilo Bangert <bangert@gentoo.org>
   laptop-mode-tools-1.47-r1.ebuild:
diff --git a/app-laptop/laptop-mode-tools/laptop-mode-tools-1.52.ebuild b/app-laptop/laptop-mode-tools/laptop-mode-tools-1.52.ebuild
new file mode 100644
index 000000000000..491803508b63
--- /dev/null
+++ b/app-laptop/laptop-mode-tools/laptop-mode-tools-1.52.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/laptop-mode-tools-1.52.ebuild,v 1.1 2009/10/16 18:42:23 bangert Exp $
+
+EAPI="2"
+
+inherit eutils
+
+MY_P="${PN}_${PV}"
+
+DESCRIPTION="Linux kernel laptop_mode user-space utilities"
+HOMEPAGE="http://www.samwel.tk/laptop_mode/"
+SRC_URI="http://www.samwel.tk/laptop_mode/tools/downloads/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+IUSE="acpi apm bluetooth hal scsi"
+
+DEPEND=""
+
+RDEPEND="sys-apps/ethtool
+		acpi? ( sys-power/acpid )
+		apm? ( sys-apps/apmd )
+		bluetooth? (
+			|| (
+				net-wireless/bluez
+				net-wireless/bluez-utils
+			)
+		)
+		hal? ( sys-apps/hal )
+		scsi? ( sys-apps/sdparm )
+		sys-apps/hdparm"
+
+S="${WORKDIR}/${MY_P}"
+
+src_compile() {
+	:
+}
+
+src_install() {
+	dodir /etc/pm/sleep.d
+	DESTDIR="${D}" \
+		MAN_D="/usr/share/man" \
+		INIT_D="none" \
+		APM="$(use apm && echo force || echo disabled)" \
+		ACPI="$(use acpi && echo force || echo disabled)" \
+		PMU="$(false && echo force || echo disabled)" \
+		./install.sh || die "Install failed."
+
+	dodoc Documentation/laptop-mode.txt README
+	newinitd "${FILESDIR}"/laptop_mode.init-1.4 laptop_mode
+
+	exeinto /etc/pm/power.d
+	newexe "${FILESDIR}"/laptop_mode_tools.pmutils laptop_mode_tools
+}
+
+pkg_postinst() {
+	if ! use acpi && ! use apm; then
+		ewarn
+		ewarn "Without USE=\"acpi\" or USE=\"apm\" ${PN} can not"
+		ewarn "automatically disable laptop_mode on low battery."
+		ewarn
+		ewarn "This means you can lose up to 10 minutes of work if running"
+		ewarn "out of battery while laptop_mode is enabled."
+		ewarn
+		ewarn "Please see /usr/share/doc/${PF}/laptop-mode.txt.gz for further"
+		ewarn "information."
+		ewarn
+	fi
+}