Add mta USE for --enable-mailto, bug#382415

(Portage version: 2.2.0_alpha154/cvs/Linux x86_64, unsigned Manifest commit)

4 files changed, 136 insertions, 4 deletions

diff --git a/app-crypt/gnupg/ChangeLog b/app-crypt/gnupg/ChangeLog
index a16619f624ff..631c0f1e6754 100644
--- a/app-crypt/gnupg/ChangeLog
+++ b/app-crypt/gnupg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-crypt/gnupg
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.454 2013/01/13 19:41:15 alonbl Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.455 2013/01/19 20:12:23 alonbl Exp $
+
+*gnupg-1.4.13-r1 (19 Jan 2013)
+
+  19 Jan 2013; Alon Bar-Lev <alonbl@gentoo.org> +gnupg-1.4.13-r1.ebuild,
+  gnupg-2.0.19-r1.ebuild, metadata.xml:
+  Add mta USE for --enable-mailto, bug#382415
 
   13 Jan 2013; Alon Bar-Lev <alonbl@gentoo.org> -gnupg-1.4.11.ebuild,
   -gnupg-1.4.12.ebuild, -gnupg-2.0.17-r2.ebuild, -gnupg-2.0.17-r3.ebuild,
diff --git a/app-crypt/gnupg/gnupg-1.4.13-r1.ebuild b/app-crypt/gnupg/gnupg-1.4.13-r1.ebuild
new file mode 100644
index 000000000000..d5ba5f82a520
--- /dev/null
+++ b/app-crypt/gnupg/gnupg-1.4.13-r1.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-1.4.13-r1.ebuild,v 1.1 2013/01/19 20:12:23 alonbl Exp $
+
+EAPI="4"
+
+inherit eutils flag-o-matic toolchain-funcs
+
+ECCVER="0.2.0"
+ECCVER_GNUPG="1.4.9"
+ECC_PATCH="${PN}-${ECCVER_GNUPG}-ecc${ECCVER}.diff"
+MY_P=${P/_/}
+
+DESCRIPTION="The GNU Privacy Guard, a GPL pgp replacement"
+HOMEPAGE="http://www.gnupg.org/"
+SRC_URI="mirror://gnupg/gnupg/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-macos"
+IUSE="bzip2 curl ldap mta nls readline selinux smartcard static usb zlib linguas_ru"
+
+COMMON_DEPEND="
+	ldap? ( net-nds/openldap )
+	bzip2? ( app-arch/bzip2 )
+	zlib? ( sys-libs/zlib )
+	curl? ( net-misc/curl )
+	mta? ( virtual/mta )
+	readline? ( sys-libs/readline )
+	smartcard? ( =virtual/libusb-0* )
+	usb? ( =virtual/libusb-0* )"
+
+RDEPEND="!static? ( ${COMMON_DEPEND} )
+	selinux? ( sec-policy/selinux-gpg )
+	nls? ( virtual/libintl )"
+
+DEPEND="${COMMON_DEPEND}
+	dev-lang/perl
+	nls? ( sys-devel/gettext )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# Install RU man page in right location
+	sed -e "/^man_MANS =/s/ gpg\.ru\.1//" -i doc/Makefile.in || die "sed doc/Makefile.in failed"
+
+	# Fix PIC definitions
+	sed -i -e 's:PIC:__PIC__:' mpi/i386/mpih-{add,sub}1.S intl/relocatable.c \
+		|| die "sed PIC failed"
+	sed -i -e 's:if PIC:ifdef __PIC__:' mpi/sparc32v8/mpih-mul{1,2}.S || \
+		die "sed PIC failed"
+}
+
+src_configure() {
+	# Certain sparc32 machines seem to have trouble building correctly with
+	# -mcpu enabled.  While this is not a gnupg problem, it is a temporary
+	# fix until the gcc problem can be tracked down.
+	if [ "${ARCH}" == "sparc" ] && [ "${PROFILE_ARCH}" == "sparc" ]; then
+		filter-flags -mcpu=supersparc -mcpu=v8 -mcpu=v7
+	fi
+
+	# 'USE=static' support was requested in #29299
+	use static && append-ldflags -static
+
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_enable ldap) \
+		$(use_enable mta mailto) \
+		--enable-hkp \
+		--enable-finger \
+		$(use_with !zlib included-zlib) \
+		$(use_with curl libcurl /usr) \
+		$(use_enable nls) \
+		$(use_enable bzip2) \
+		$(use_enable smartcard card-support) \
+		$(use_enable selinux selinux-support) \
+		--without-capabilities \
+		$(use_with readline) \
+		$(use_with usb libusb /usr) \
+		--enable-static-rnd=linux \
+		--libexecdir="${EPREFIX}/usr/libexec" \
+		--enable-noexecstack \
+		CC_FOR_BUILD=$(tc-getBUILD_CC) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	# keep the documentation in /usr/share/doc/...
+	rm -rf "${ED}usr/share/gnupg/FAQ" "${ED}usr/share/gnupg/faq.html" || die
+
+	dodoc AUTHORS BUGS ChangeLog NEWS PROJECTS README THANKS \
+		TODO VERSION doc/{FAQ,HACKING,DETAILS,OpenPGP}
+
+	exeinto /usr/libexec/gnupg
+	doexe tools/make-dns-cert
+
+	# install RU documentation in right location
+	if use linguas_ru; then
+		cp doc/gpg.ru.1 "${T}/gpg.1" || die
+		doman -i18n=ru "${T}/gpg.1"
+	fi
+}
+
+pkg_postinst() {
+	ewarn "If you are using a non-Linux system, or a kernel older than 2.6.9,"
+	ewarn "you MUST make the gpg binary setuid."
+	echo
+#	if use !bindist && use ecc; then
+#		ewarn
+#		ewarn "The elliptical curves patch is experimental"
+#		ewarn "Further info available at http://alumnes.eps.udl.es/%7Ed4372211/index.en.html"
+#	fi
+	elog
+	elog "See http://www.gentoo.org/doc/en/gnupg-user.xml for documentation on gnupg"
+	elog
+	elog "If you wish to view images emerge:"
+	elog "media-gfx/xloadimage, media-gfx/xli or any other viewer"
+	elog "Remember to use photo-viewer option in configuration file to activate the right viewer"
+}
diff --git a/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild b/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild
index f71934b575f1..e941338dde3f 100644
--- a/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild
+++ b/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild,v 1.2 2013/01/12 20:46:31 alonbl Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.19-r1.ebuild,v 1.3 2013/01/19 20:12:23 alonbl Exp $
 
 EAPI="4"
 
@@ -14,7 +14,7 @@ SRC_URI="mirror://gnupg/gnupg/${P}.tar.bz2"
 LICENSE="GPL-3"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="adns bzip2 doc ldap nls readline static selinux smartcard usb"
+IUSE="adns bzip2 doc ldap nls mta readline static selinux smartcard usb"
 
 COMMON_DEPEND_LIBS="
 	>=dev-libs/libassuan-2
@@ -49,7 +49,7 @@ DEPEND="${COMMON_DEPEND_LIBS}
 
 RDEPEND="!static? ( ${COMMON_DEPEND_LIBS} )
 	${COMMON_DEPEND_BINS}
-	virtual/mta
+	mta? ( virtual/mta )
 	!<=app-crypt/gnupg-2.0.1
 	selinux? ( sec-policy/selinux-gpg )
 	nls? ( virtual/libintl )"
@@ -84,6 +84,7 @@ src_configure() {
 		$(use_enable bzip2) \
 		$(use_enable !elibc_SunOS symcryptrun) \
 		$(use_enable nls) \
+		$(use_enable mta mailto) \
 		$(use_enable ldap) \
 		$(use_with readline) \
 		CC_FOR_BUILD="$(tc-getBUILD_CC)"
diff --git a/app-crypt/gnupg/metadata.xml b/app-crypt/gnupg/metadata.xml
index c7353c640b37..10f7c80896d7 100644
--- a/app-crypt/gnupg/metadata.xml
+++ b/app-crypt/gnupg/metadata.xml
@@ -21,5 +21,9 @@
       Build direct CCID access for scdaemon; requires
       <pkg>dev-libs/libusb</pkg>.
     </flag>
+    <flag name='mta'>
+      Build mta support using
+      <pkg>virtual/mta</pkg>.
+    </flag>
   </use>
 </pkgmetadata>