Version bump.

(Portage version: 2.1.2.4)

3 files changed, 157 insertions, 1 deletions

diff --git a/app-cdr/k3b/ChangeLog b/app-cdr/k3b/ChangeLog
index 7bf81f872cbf..fffa57ec6b18 100644
--- a/app-cdr/k3b/ChangeLog
+++ b/app-cdr/k3b/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-cdr/k3b
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.189 2007/04/14 16:21:33 carlo Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/ChangeLog,v 1.190 2007/04/19 11:23:57 carlo Exp $
+
+*k3b-1.0.1 (19 Apr 2007)
+
+  19 Apr 2007; Carsten Lohrke <carlo@gentoo.org> +k3b-1.0.1.ebuild:
+  Version bump.
 
   14 Apr 2007; Carsten Lohrke <carlo@gentoo.org> k3b-1.0.ebuild:
   Fix bug #174554.
diff --git a/app-cdr/k3b/files/digest-k3b-1.0.1 b/app-cdr/k3b/files/digest-k3b-1.0.1
new file mode 100644
index 000000000000..63b5aa46b748
--- /dev/null
+++ b/app-cdr/k3b/files/digest-k3b-1.0.1
@@ -0,0 +1,6 @@
+MD5 8abd11f56e6e40d6f2d0b076a5f8b8ed k3b-1.0.1.tar.bz2 5097997
+RMD160 e4eeab9bec1a2ac222ed91fd6688a3c272ec7670 k3b-1.0.1.tar.bz2 5097997
+SHA256 609c56d4a9e0b41d545e377d61904e99a46e878280d6a6651a65f72f94acb65e k3b-1.0.1.tar.bz2 5097997
+MD5 f87a27408a4153d860103816ba83db09 k3b-i18n-1.0.1.tar.bz2 6839893
+RMD160 9f87c03e25ede1a93088aa589a3e66942974224c k3b-i18n-1.0.1.tar.bz2 6839893
+SHA256 e3359f08873833726dd6f7adc830c05d2d33636e5d4b56e43f8dee6b531347ce k3b-i18n-1.0.1.tar.bz2 6839893
diff --git a/app-cdr/k3b/k3b-1.0.1.ebuild b/app-cdr/k3b/k3b-1.0.1.ebuild
new file mode 100644
index 000000000000..e7e6bb8a7eb2
--- /dev/null
+++ b/app-cdr/k3b/k3b-1.0.1.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/k3b/k3b-1.0.1.ebuild,v 1.1 2007/04/19 11:23:57 carlo Exp $
+
+inherit kde eutils
+
+MY_P=${P/_/}
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="K3b, KDE CD Writing Software"
+HOMEPAGE="http://www.k3b.org/"
+SRC_URI="mirror://sourceforge/k3b/${MY_P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa css dvdr dvdread encode ffmpeg flac hal kde mp3 musepack musicbrainz
+	sndfile vcd vorbis emovix"
+
+DEPEND="kde? ( || ( kde-base/kdesu kde-base/kdebase ) )
+	hal? ( || ( dev-libs/dbus-qt3-old
+				( <sys-apps/dbus-0.90 >=sys-apps/dbus-0.30 ) )
+		sys-apps/hal )
+	media-libs/libsamplerate
+	media-libs/taglib
+	>=media-sound/cdparanoia-3.9.8
+	sndfile? ( media-libs/libsndfile )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? ( media-libs/flac )
+	mp3? ( media-libs/libmad )
+	musepack? ( media-libs/libmpcdec )
+	vorbis? ( media-libs/libvorbis )
+	musicbrainz? ( media-libs/musicbrainz )
+	encode? ( media-sound/lame )
+	alsa? ( media-libs/alsa-lib )
+	dvdread? ( media-libs/libdvdread )"
+
+RDEPEND="${DEPEND}
+	virtual/cdrtools
+	>=app-cdr/cdrdao-1.1.7-r3
+	media-sound/normalize
+	dvdr? ( >=app-cdr/dvd+rw-tools-7.0 )
+	css? ( media-libs/libdvdcss )
+	encode? ( media-sound/sox
+			  media-video/transcode )
+	vcd? ( media-video/vcdimager )
+	emovix? ( media-video/emovix )"
+
+DEPEND="${DEPEND}
+	dev-util/pkgconfig"
+
+need-kde 3.5
+
+# The following commented lines will have to be uncommented once the final
+# release is done. This pre-release version does not support i18n.
+I18N="${PN}-i18n-${PV}"
+
+# Supported languages and translated documentation
+LANGS="af ar bg br bs ca cs cy da de el en_GB es et eu fa fi fr ga gl he hi hu is it ja ka lt mk ms nb nds nl nn pa pl pt pt_BR ru rw se sk sr sr@Latn sv ta tr uk uz zh_CN zh_TW"
+for X in ${LANGS}; do
+	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/k3b/${I18N}.tar.bz2 )"
+	IUSE="${IUSE} linguas_${X}"
+done
+
+pkg_setup() {
+	if use hal && has_version '<sys-apps/dbus-0.91' && ! built_with_use sys-apps/dbus qt3; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"hal\" USE flag enabled,"
+		eerror "but sys-apps/dbus is not built with Qt3 support."
+		die "Please, rebuild sys-apps/dbus with the \"qt3\" USE flag."
+	fi
+	if use encode && ! built_with_use media-video/transcode dvdread; then
+		eerror "You are trying to compile ${CATEGORY}/${PF} with the \"encode\""
+		eerror "USE flag enabled, however media-video/transcode was not built"
+		eerror "with libdvdread support. Also keep in mind that enabling"
+		eerror "the dvdread USE flag will cause k3b to use libdvdread as well."
+		die "Please, rebuild media-video/transcode with the \"dvdread\" USE flag."
+	fi
+
+	use kde || elog "You haven't set the kde use flag. k3bsetup won't be installed."
+
+	kde_pkg_setup
+}
+
+src_unpack() {
+	kde_src_unpack
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		cd "${WORKDIR}/${I18N}"
+		for X in ${LANGS}; do
+			use linguas_${X} || rm -rf "${X}"
+		done
+		rm -f configure
+	fi
+
+	rm -f "${S}/configure"
+}
+
+src_compile() {
+	local myconf="--enable-libsuffix= 		\
+			--with-external-libsamplerate	\
+			--without-resmgr				\
+			--without-cdrecord-suid-root	\
+			$(use_with kde k3bsetup)		\
+			$(use_with hal)					\
+			$(use_with encode lame)			\
+			$(use_with ffmpeg)				\
+			$(use_with flac)				\
+			$(use_with vorbis oggvorbis)	\
+			$(use_with sndfile)				\
+			$(use_with mp3 libmad)			\
+			$(use_with musepack)			\
+			$(use_with musicbrainz)			\
+			$(use_with alsa)"
+
+	# Build process of K3b
+	kde_src_compile
+
+	# Build process of K3b-i18n
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		KDE_S="${WORKDIR}/${I18N}" \
+		kde_src_compile
+	fi
+}
+
+src_install() {
+	kde_src_install
+	dodoc FAQ KNOWNBUGS PERMISSIONS
+
+	if [ -d "${WORKDIR}/${I18N}" ]; then
+		KDE_S="${WORKDIR}/${I18N}" \
+		kde_src_install
+	fi
+}
+
+pkg_preinst() {
+	kde_pkg_preinst
+	use kde || rm ${D}/usr/share/applications/kde/k3bsetup2.desktop
+}
+
+pkg_postinst() {
+	echo
+	elog "Make sure you have proper read/write permissions on the cdrom device(s)."
+	elog "Usually, it is sufficient to be in the cdrom group."
+	echo
+}