Revision bump: EAPI 5, add output about selected firewall backend through einfo

(Portage version: 2.2.0_alpha153/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 66 insertions, 2 deletions

diff --git a/app-admin/sshguard/ChangeLog b/app-admin/sshguard/ChangeLog
index f73c83f85fb8..0179b9711253 100644
--- a/app-admin/sshguard/ChangeLog
+++ b/app-admin/sshguard/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/sshguard
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/sshguard/ChangeLog,v 1.17 2012/01/17 18:19:10 jer Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/sshguard/ChangeLog,v 1.18 2013/01/17 08:14:33 pinkbyte Exp $
+
+*sshguard-1.5-r2 (17 Jan 2013)
+
+  17 Jan 2013; Sergey Popov <pinkbyte@gentoo.org> +sshguard-1.5-r2.ebuild:
+  Revision bump: EAPI 5, add output about selected firewall backend through
+  einfo
 
   17 Jan 2012; Jeroen Roovers <jer@gentoo.org> -sshguard-1.0.ebuild,
   -sshguard-1.1.ebuild, -sshguard-1.3.ebuild, -sshguard-1.4.ebuild:
diff --git a/app-admin/sshguard/sshguard-1.5-r2.ebuild b/app-admin/sshguard/sshguard-1.5-r2.ebuild
new file mode 100644
index 000000000000..86008f279bfe
--- /dev/null
+++ b/app-admin/sshguard/sshguard-1.5-r2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/sshguard/sshguard-1.5-r2.ebuild,v 1.1 2013/01/17 08:14:33 pinkbyte Exp $
+
+EAPI=5
+
+inherit flag-o-matic
+
+DESCRIPTION="protects hosts from brute force attacks against ssh"
+HOMEPAGE="http://sshguard.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="ipfilter kernel_FreeBSD kernel_linux"
+
+CDEPEND="kernel_linux? ( net-firewall/iptables )
+	kernel_FreeBSD? ( !ipfilter? ( sys-freebsd/freebsd-pf ) )"
+DEPEND="${CDEPEND}
+	sys-devel/flex"
+RDEPEND="${CDEPEND}
+	sys-apps/openrc
+	virtual/logger"
+
+DOCS=( README Changes scripts/sshguard_backendgen.sh )
+
+src_prepare() {
+	sed -i configure -e '/OPTIMIZER_CFLAGS=/d' || die
+}
+
+src_configure() {
+	# Needed for usleep(3), see "nasty" in src/sshguard_logsuck.c
+	append-flags -D_BSD_SOURCE
+
+	local myconf
+	if use kernel_linux; then
+		einfo "Selected firewall backend: iptables"
+		myconf="--with-firewall=iptables"
+	elif use kernel_FreeBSD; then
+		if use ipfilter; then
+			einfo "Selected firewall backend: ipfw"
+			myconf="--with-firewall=ipfw"
+		else
+			einfo "Selected firewall backend: pf"
+			myconf="--with-firewall=pf"
+		fi
+	fi
+
+	econf ${myconf}
+}
+
+src_install() {
+	default
+	dodoc examples/*
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}