From cafbd5bd57e505ad11c0bf5610acd39a21878083 Mon Sep 17 00:00:00 2001
From: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Date: Sat, 14 Oct 2023 13:51:36 +0200
Subject: net-vpn/eduvpn-common: new package, add 1.1.2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Mario Haustein <mario.haustein@hrz.tu-chemnitz.de>
Acked-by: Sam James <sam@gentoo.org>
Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 net-vpn/eduvpn-common/Manifest                   |  2 +
 net-vpn/eduvpn-common/eduvpn-common-1.1.2.ebuild | 74 ++++++++++++++++++++++++
 net-vpn/eduvpn-common/metadata.xml               | 28 +++++++++
 3 files changed, 104 insertions(+)
 create mode 100644 net-vpn/eduvpn-common/Manifest
 create mode 100644 net-vpn/eduvpn-common/eduvpn-common-1.1.2.ebuild
 create mode 100644 net-vpn/eduvpn-common/metadata.xml

(limited to 'net-vpn')

diff --git a/net-vpn/eduvpn-common/Manifest b/net-vpn/eduvpn-common/Manifest
new file mode 100644
index 000000000000..eee90b353fe8
--- /dev/null
+++ b/net-vpn/eduvpn-common/Manifest
@@ -0,0 +1,2 @@
+DIST eduvpn-common-1.1.2-deps.tar.xz 7517364 BLAKE2B a6bd2c11d5056170d88ca8c35d054cd6d529462af6595fe31c535640cdf59a25ae4811c04bc738832fa4c28d2d3308ca5615170547b0c93edf7c4dd3f475978b SHA512 ce167298a76df4e22b23e3cfb7640f0272ea546dc5767f66baab900029c2a4850b383521d2f74ae0d77c53f47ba6eb51d80ab122362e4a7470e69a1fc3ac423f
+DIST eduvpn-common-1.1.2.gh.tar.gz 208300 BLAKE2B 8cb7e96d4a6a5032a1696aa57a6322f6a861aebba8b1f653d8be98e0044eacb3f23dc400ac9a8598dd83f30ca2140394ee2aa5733a27547f2a0378ad03ab422d SHA512 dbc290e48bc045456ad83e58e63c223cef5a7e1c7178537a44ed306a423276e644fb0f5607a7d8ddc5014b48ae11b57e365068d72887062277f8ab4f6f1ae660
diff --git a/net-vpn/eduvpn-common/eduvpn-common-1.1.2.ebuild b/net-vpn/eduvpn-common/eduvpn-common-1.1.2.ebuild
new file mode 100644
index 000000000000..21519b3a39d0
--- /dev/null
+++ b/net-vpn/eduvpn-common/eduvpn-common-1.1.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+inherit distutils-r1 go-module linux-info
+
+DESCRIPTION="Linux client and Python client API for eduVPN"
+HOMEPAGE="https://www.eduvpn.org/"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/eduvpn/eduvpn-common.git"
+else
+	SRC_URI="
+		https://github.com/eduvpn/eduvpn-common/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz
+		https://www-user.tu-chemnitz.de/~hamari/eduvpn/${P}-deps.tar.xz
+	"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="openvpn wireguard"
+RESTRICT="test"
+
+RDEPEND="
+	openvpn? ( net-vpn/openvpn )
+"
+
+wrap_python() {
+	local phase=$1
+	shift
+
+	pushd wrappers/python >/dev/null || die
+	distutils-r1_${phase} "$@"
+	popd >/dev/null || die
+}
+
+pkg_pretend() {
+	if use wireguard; then
+		CONFIG_CHECK="~WIREGUARD"
+		WARNING_WIREGUARD="You must enable WIREGUARD to use wireguard."
+		check_extra_config
+	fi
+}
+
+src_prepare() {
+	default
+
+	mkdir -p wrappers/python/eduvpn_common/lib || die
+
+	wrap_python ${FUNCNAME}
+}
+
+src_compile() {
+	default
+	wrap_python ${FUNCNAME}
+}
+
+src_test() {
+	default
+	wrap_python ${FUNCNAME}
+}
+
+src_install() {
+	# The shared library is installed within the python package. There is no
+	# need to call the default routine.
+	wrap_python ${FUNCNAME}
+}
diff --git a/net-vpn/eduvpn-common/metadata.xml b/net-vpn/eduvpn-common/metadata.xml
new file mode 100644
index 000000000000..26731a22c57e
--- /dev/null
+++ b/net-vpn/eduvpn-common/metadata.xml
@@ -0,0 +1,28 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>mario.haustein@hrz.tu-chemnitz.de</email>
+		<name>Mario Haustein</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription>
+		Code to be shared between eduVPN clients
+
+		eduVPN is a frontend for either WireGuard or OpenVPN used widely at
+		european academic institutions. It features an easy to use VPN
+		configuration utility. Users just need to login occasionally with their
+		credentials issued by the institution to refresh their VPN
+		configuration.
+	</longdescription>
+	<use>
+		<flag name="openvpn">enable support for OpenVPN</flag>
+		<flag name="wireguard">enable support for WireGuard</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">eduvpn/eduvpn-common</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad