blob: ee6d9372bafe859b4f53402e13c967436a5b3dca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit qmake-utils
DESCRIPTION="Modern build tool for software projects"
HOMEPAGE="https://wiki.qt.io/Qbs"
SRC_URI="https://github.com/qt-labs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="|| ( LGPL-2.1 LGPL-3 )"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="doc examples test"
# see bug 581874 for the qttest dep in RDEPEND
RDEPEND="
dev-qt/qtcore:5=
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtscript:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
test? ( dev-qt/qttest:5 )
"
DEPEND="${RDEPEND}
doc? (
dev-qt/qdoc:5
dev-qt/qthelp:5
)
test? ( dev-qt/qtdeclarative:5 )
"
src_prepare() {
default
# don't add /usr/include to INCLUDEPATH
# avoids a build failure in qt-creator with gcc-6 (bug 618424)
sed -i -e '/^INCLUDEPATH/ s:$${PWD}/\.\.::' src/lib/corelib/use_installed_corelib.pri || die
if ! use examples; then
sed -i -e '/INSTALLS +=/ s:examples::' static.pro || die
fi
if use test; then
sed -i -e '/SUBDIRS =/ s:=.*:= auto:' tests/tests.pro || die
else
sed -i -e '/SUBDIRS =/ d' tests/tests.pro || die
fi
# skip several tests that fail and/or have additional deps
sed -i \
-e 's/findArchiver("7z")/""/' `# requires p7zip, fails` \
-e 's/findArchiver(binaryName,.*/"";/' `# requires zip and jar` \
-e 's/p\.value("nodejs\./true||&/' `# requires nodejs, bug 527652` \
-e 's/\(p\.value\|m_qbsStderr\.contains\)("typescript\./true||&/' `# requires nodejs and typescript` \
tests/auto/blackbox/tst_blackbox.cpp || die
# requires jdk, fails, bug 585398
sed -i -e '/blackbox-java\.pro/ d' tests/auto/auto.pro || die
}
src_configure() {
local myqmakeargs=(
qbs.pro # bug 523218
-recursive
CONFIG+=qbs_disable_rpath
CONFIG+=qbs_enable_project_file_updates
$(usex test 'CONFIG+=qbs_enable_unit_tests' '')
QBS_INSTALL_PREFIX="${EPREFIX}/usr"
QBS_LIBRARY_DIRNAME="$(get_libdir)"
)
eqmake5 "${myqmakeargs[@]}"
}
src_test() {
einfo "Setting up test environment in ${T}"
export HOME=${T}
export LD_LIBRARY_PATH=${S}/$(get_libdir)
"${S}"/bin/qbs-setup-toolchains /usr/bin/gcc gcc || die
"${S}"/bin/qbs-setup-qt "$(qt5_get_bindir)/qmake" qbs_autotests || die
einfo "Running autotests"
# simply exporting LD_LIBRARY_PATH doesn't work
# we have to use a custom testrunner script
local testrunner=${WORKDIR}/gentoo-testrunner
cat <<-EOF > "${testrunner}"
#!/bin/sh
export LD_LIBRARY_PATH="${LD_LIBRARY_PATH}\${LD_LIBRARY_PATH:+:}\${LD_LIBRARY_PATH}"
exec "\$@"
EOF
chmod +x "${testrunner}"
emake TESTRUNNER="'${testrunner}'" check
}
src_install() {
emake INSTALL_ROOT="${D}" install
# install documentation
if use doc; then
emake docs
dodoc -r doc/qbs/html
dodoc doc/qbs.qch
docompress -x /usr/share/doc/${PF}/qbs.qch
fi
}
|
GitWeb