dev-java/commons-lang/commons-lang-2.6-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

JAVA_PKG_IUSE="doc source test"
MAVEN_ID="commons-lang:commons-lang:2.6"
JAVA_PKG_WANT_SOURCE="1.4"
JAVA_PKG_WANT_TARGET="1.4"

inherit java-pkg-2 java-ant-2 verify-sig

DESCRIPTION="Commons components to manipulate core java classes"
HOMEPAGE="https://commons.apache.org/proper/commons-lang/"
SRC_URI="mirror://apache/commons/lang/source/${P}-src.tar.gz
	verify-sig? ( https://downloads.apache.org/commons/lang/source/${P}-src.tar.gz.asc  )"

LICENSE="Apache-2.0"
SLOT="2.1"
KEYWORDS="amd64 ~arm arm64 ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-solaris"

DEPEND="virtual/jdk:1.8
	test? (
		dev-java/ant-junit:0
	)"

RDEPEND="virtual/jre:1.8"

BDEPEND="verify-sig? ( sec-keys/openpgp-keys-apache-commons )"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/commons.apache.org.asc"

S="${WORKDIR}/${P}-src"

JAVA_ANT_ENCODING="ISO-8859-1"

src_install() {
	java-pkg_newjar "target/${P}.jar" "${PN}.jar"
	dodoc RELEASE-NOTES.txt NOTICE.txt
	docinto html
	dodoc *.html
	use doc && java-pkg_dojavadoc target/apidocs
	use source && java-pkg_dosrc src/main/java/*
}