From 686f3527b3b4b24ba01957b492a055f0ae409335 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 15 Feb 2024 10:44:55 +0100
Subject: kde-apps/ark: 23.08.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/ark/Manifest           |  1 +
 kde-apps/ark/ark-23.08.5.ebuild | 81 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 kde-apps/ark/ark-23.08.5.ebuild

(limited to 'kde-apps/ark')

diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
index 5b1a7a079710..b069f2ad405e 100644
--- a/kde-apps/ark/Manifest
+++ b/kde-apps/ark/Manifest
@@ -1 +1,2 @@
 DIST ark-23.08.4.tar.xz 3017820 BLAKE2B 85a1e5bbf35e12721ca8f4c68dd5d71e9c04727c4b1e4a3803589b418368c44c30766680ec6a21abfa7b7549a66edbb8bb051aecce436990cbf7b7298da5e8c9 SHA512 745c922c52192c61b80f928d4ffdbaee36c98b17d49308fa02daa27966753be5373af460efad1df75396b0cc534020e7873122faba5d83f76bfc1f0a68236be5
+DIST ark-23.08.5.tar.xz 3018696 BLAKE2B 482a17aa9bf72abbaa75510451ba0dd59812d2cd2aca97efda0f4f1c78f98060d9f654efd0387aeae35d5220304f00139520a6836451056b84064cc8d8b12d16 SHA512 8fab4281f5cfe34938f7a958e2889ad4dabff6613b1e3a8fed1efb2039dbf35a71d99494869037fd821515ecfba6e44304bb0907c27afd646fe7496783735336
diff --git a/kde-apps/ark/ark-23.08.5.ebuild b/kde-apps/ark/ark-23.08.5.ebuild
new file mode 100644
index 000000000000..b6276fedc261
--- /dev/null
+++ b/kde-apps/ark/ark-23.08.5.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org optfeature
+
+DESCRIPTION="File archiver by KDE"
+HOMEPAGE="https://apps.kde.org/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="zip"
+
+RDEPEND="
+	>=app-arch/libarchive-3.5.3:=[bzip2,lzma]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.6.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	test? ( >=dev-libs/libzip-1.6.0:= )
+"
+# app-arch/rar is binary only
+BDEPEND="
+	sys-devel/gettext
+	elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package zip LibZip)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# bug 822177: kerfuffle-addtoarchivetest: may segfault or hang indefinitely
+		# bug 827840: plugins-clirartest: continuously broken with translations installed
+		-E "(kerfuffle-addtoarchivetest|plugins-clirartest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "rar archive creation/extraction" "app-arch/rar"
+		optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
+		optfeature "7-Zip archive support" "app-arch/p7zip"
+		optfeature "lrz archive support" "app-arch/lrzip"
+		optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
+	fi
+	ecm_pkg_postinst
+}
-- 
cgit v1.2.3-65-gdbad