From aaf9578fdb49534f1a77ff024758680a84e90354 Mon Sep 17 00:00:00 2001
From: Andreas Zuber <a.zuber@gmx.ch>
Date: Thu, 10 Dec 2020 09:30:22 +0100
Subject: games-util/pyfa: cleanup old version

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Andreas Zuber <a.zuber@gmx.ch>
Closes: https://github.com/gentoo/gentoo/pull/18591
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 games-util/pyfa/Manifest           |  1 -
 games-util/pyfa/pyfa-2.31.0.ebuild | 92 --------------------------------------
 2 files changed, 93 deletions(-)
 delete mode 100644 games-util/pyfa/pyfa-2.31.0.ebuild

(limited to 'games-util')

diff --git a/games-util/pyfa/Manifest b/games-util/pyfa/Manifest
index b06009417f6d..2525a451acd5 100644
--- a/games-util/pyfa/Manifest
+++ b/games-util/pyfa/Manifest
@@ -1,3 +1,2 @@
-DIST pyfa-2.31.0.tar.gz 28138681 BLAKE2B a183fa073a34f0db1264aae980e36e28e90374153e372bcb14cf3a0c3e3c1ff95084f8c23a9710a169671d12ec830e3203d1eb072d1dfc1d9c1095e0422bccfb SHA512 813ca3f7f43b08ceceb1e607ddbc2ff0b47836823dde91787da2c3905fd9af2fdddfa582ec867dd4311f14f4180cc8ec993a49f0ed62b6ce68d4eed6060c3c5b
 DIST pyfa-2.32.0.tar.gz 28170873 BLAKE2B 92839a83067f3699dfcf85a6e479c16a80e18f375f402654dd2b1207497bfba639e717d3ff205cc682a8cbf3cefd37990c7d6dccf46e9dbf23bfd416c58eba81 SHA512 998a1055a5d68cdf61603ecac503db24a8ea344cd388acc7f1f04aafe54b22db059461619c1a1d93b807dc64c779a158b6b2d5066412d6ffc3df0a858de83b0e
 DIST pyfa-2.33.0.tar.gz 28872031 BLAKE2B fe7fad57e43a8efc78f828d0ff81788147fa64ef02a20a71d6fef8ab0130d39b5ebffc18d58a774a61d805b8d0e570cbedb0b8fa536c8c71e61102fb6d093998 SHA512 bfa4e41b387e9f23aeae41a4884a0492316cc6e51841243ef56dc733edab10e6c9609ca7918d4de9fcd052b4da8f8048ce7578d164ad98237b53cb05f7c168d8
diff --git a/games-util/pyfa/pyfa-2.31.0.ebuild b/games-util/pyfa/pyfa-2.31.0.ebuild
deleted file mode 100644
index 50ffcdd37c25..000000000000
--- a/games-util/pyfa/pyfa-2.31.0.ebuild
+++ /dev/null
@@ -1,92 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="7"
-
-PYTHON_COMPAT=( python3_{6,7,8} )
-PYTHON_REQ_USE="sqlite"
-
-inherit desktop edos2unix python-single-r1 xdg
-
-DESCRIPTION="Python Fitting Assistant - a ship fitting application for EVE Online"
-HOMEPAGE="https://github.com/pyfa-org/Pyfa"
-
-LICENSE="GPL-3+ all-rights-reserved"
-SLOT="0"
-if [[ ${PV} = 9999 ]]; then
-	EGIT_REPO_URI="https://github.com/pyfa-org/Pyfa.git"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/pyfa-org/Pyfa/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
-	S="${WORKDIR}/Pyfa-${PV}"
-fi
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-RESTRICT="mirror bindist"
-
-DEPEND="
-	$(python_gen_cond_dep '
-		>=dev-python/cryptography-2.3[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/logbook-1.0.0[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/pyyaml-5.1[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/sqlalchemy-1.3.0[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/wxpython-4.0.6[webkit,${PYTHON_MULTI_USEDEP}]
-	')
-	${PYTHON_DEPS}"
-RDEPEND="${DEPEND}
-	$(python_gen_cond_dep '
-		>=dev-python/beautifulsoup-4.6.0[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/markdown2-2.3.5[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/packaging-16.8[${PYTHON_MULTI_USEDEP}]
-		dev-python/python-dateutil[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/requests-2.0.0[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/roman-2.0.0[${PYTHON_MULTI_USEDEP}]
-		>=dev-python/matplotlib-3.1.2[wxwidgets,${PYTHON_MULTI_USEDEP}]
-	')"
-BDEPEND="app-arch/zip"
-
-PATCHES=(
-	# fix import path in the main script for systemwide installation
-	"${FILESDIR}/${PN}-2.9.3-import-pyfa.patch"
-)
-
-src_prepare() {
-	# get rid of CRLF line endings introduced in 1.1.10 so patches work
-	edos2unix config.py pyfa.py gui/bitmap_loader.py service/settings.py
-
-	default
-
-	# make python recognize pyfa as a package
-	touch __init__.py || die
-
-	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
-		-e "s:%%EPREFIX%%:${EPREFIX}:" \
-		"${FILESDIR}/configforced-1.15.1.py" > configforced.py || die
-	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
-		pyfa.py > pyfa || die
-}
-
-src_install() {
-	python_moduleinto ${PN}
-	python_domodule eos gui service utils graphs
-	python_domodule config*.py __init__.py version.yml configforced.py db_update.py
-	python_doscript pyfa
-
-	insinto /usr/share/${PN}
-
-	einfo "Creating database ..."
-	${EPYTHON} ./db_update.py || die
-	doins eve.db
-
-	einfo "Compressing images ..."
-	pushd imgs > /dev/null || die
-	zip -r imgs.zip * || die "zip failed"
-	doins imgs.zip
-	popd > /dev/null || die
-
-	dodoc README.md
-	doicon -s 32 imgs/gui/pyfa.png
-	newicon -s 64 imgs/gui/pyfa64.png pyfa.png
-	domenu "${FILESDIR}/${PN}.desktop"
-}
-- 
cgit v1.2.3-65-gdbad