From a663ab344d4deebd60dc35994eb659579412754d Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 25 Nov 2020 22:35:16 +0100
Subject: dev-qt: Add Qt 5.15.2

Package-Manager: Portage-3.0.10, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-qt/qtmultimedia/Manifest                   |  1 +
 dev-qt/qtmultimedia/qtmultimedia-5.15.2.ebuild | 68 ++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)
 create mode 100644 dev-qt/qtmultimedia/qtmultimedia-5.15.2.ebuild

(limited to 'dev-qt/qtmultimedia')

diff --git a/dev-qt/qtmultimedia/Manifest b/dev-qt/qtmultimedia/Manifest
index 388380dc4ea5..3a9b595dbbbc 100644
--- a/dev-qt/qtmultimedia/Manifest
+++ b/dev-qt/qtmultimedia/Manifest
@@ -1 +1,2 @@
 DIST qtmultimedia-everywhere-src-5.15.1.tar.xz 3825940 BLAKE2B 8a86e77b37c7af0226420025f23bcea6aaffcf885f7c56945faa8606bdaf003b29013b452ee2cd44cb1abe7adf260af06f099b7af23664110a97a0dab0574a36 SHA512 9c063dc481c91a94ba151fa96166d04a83e1cdcdb66c5fa80c038bd973c87b928c3d90d1c8add7c3ec29c4dc7dceff9e8cf288ce980f95d199f37e90593104d9
+DIST qtmultimedia-everywhere-src-5.15.2.tar.xz 3828172 BLAKE2B 6d492abdd563788e601eba8183197863f5ddf0697c8f72939f8d6de8043d0575333bc6effd17182a2b5e2e0a93d6f431054282ad34f4ea0f0a0a67e1502a948d SHA512 be58e6934976b04707399f8525dd5d50f73e0539efd1a76c2f9868e35e6f136e0991652df5d46350a9ac39d24313353e4aa826131f268a95e458e57279f448bd
diff --git a/dev-qt/qtmultimedia/qtmultimedia-5.15.2.ebuild b/dev-qt/qtmultimedia/qtmultimedia-5.15.2.ebuild
new file mode 100644
index 000000000000..f8b9dfe3d426
--- /dev/null
+++ b/dev-qt/qtmultimedia/qtmultimedia-5.15.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit qt5-build
+
+DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+IUSE="alsa gles2-only gstreamer openal pulseaudio qml widgets"
+
+RDEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2-only=]
+	~dev-qt/qtnetwork-${PV}
+	alsa? ( media-libs/alsa-lib )
+	gstreamer? (
+		dev-libs/glib:2
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-bad:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	pulseaudio? ( media-sound/pulseaudio[glib] )
+	qml? (
+		~dev-qt/qtdeclarative-${PV}
+		gles2-only? ( ~dev-qt/qtgui-${PV}[egl] )
+		openal? ( media-libs/openal )
+	)
+	widgets? (
+		~dev-qt/qtopengl-${PV}
+		~dev-qt/qtwidgets-${PV}[gles2-only=]
+	)
+"
+DEPEND="${RDEPEND}
+	gstreamer? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	sed -i -e '/CONFIG\s*+=/ s/optimize_full//' \
+		src/multimedia/multimedia.pro || die
+
+	qt_use_disable_config openal openal \
+		src/imports/imports.pro
+
+	qt_use_disable_mod qml quick \
+		src/src.pro \
+		src/plugins/plugins.pro
+
+	qt_use_disable_mod widgets widgets \
+		src/src.pro \
+		src/gsttools/gsttools.pro \
+		src/plugins/gstreamer/common.pri
+
+	qt5-build_src_prepare
+}
+
+src_configure() {
+	local myqmakeargs=(
+		--
+		$(qt_use alsa)
+		$(qt_use gstreamer)
+		$(qt_use pulseaudio)
+	)
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3-65-gdbad