From 621633ea7b70ae29ca8d1ad3e084b62338bed552 Mon Sep 17 00:00:00 2001
From: Guillermo Joandet <gjoandet@gmail.com>
Date: Sun, 10 Sep 2023 12:41:02 -0300
Subject: dev-python/pygobject: Version bump to 3.46.0

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32712
Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-python/pygobject/Manifest                |  1 +
 dev-python/pygobject/pygobject-3.46.0.ebuild | 80 ++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)
 create mode 100644 dev-python/pygobject/pygobject-3.46.0.ebuild

(limited to 'dev-python/pygobject')

diff --git a/dev-python/pygobject/Manifest b/dev-python/pygobject/Manifest
index 71f155ce5cef..8ce81ab9f53f 100644
--- a/dev-python/pygobject/Manifest
+++ b/dev-python/pygobject/Manifest
@@ -1 +1,2 @@
 DIST pygobject-3.44.1.tar.xz 559432 BLAKE2B 7edfe91ac1b7301befaf8ef17078b517666467f446bfbe25850336cd365d314153d444d29ecf028ce44a12cef1c94f139d110ac6784c8a2c6077730d4836f6cc SHA512 5f2ff4a068e7e24dcc32f8c43ba58660c85a0fabdd9ff0bac4ddf1ca82bd0fc962ce5cb3ab25b991c212d45e5e89dac67c3259c5423a7d7fd70b2ac1f56e5327
+DIST pygobject-3.46.0.tar.xz 561552 BLAKE2B 6b8c9b4bf6df819c09b7bd2ea6dcb0e7c24ed7f171487b774469bd2c4694df9d4473dbde05273afc7a370f2b1f352d60347aa221bdd674a4aa8a54123d5e54cd SHA512 48293c193ba5aece38d99f45d325d0329ac33e88442bf00848fe818a7c838977b8d2cf50a404c30e8852ccc0b4a44dfda07751d51acc21f740aa2ab6aa3ce661
diff --git a/dev-python/pygobject/pygobject-3.46.0.ebuild b/dev-python/pygobject/pygobject-3.46.0.ebuild
new file mode 100644
index 000000000000..d00e6ddaa043
--- /dev/null
+++ b/dev-python/pygobject/pygobject-3.46.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=no
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit gnome.org meson virtualx xdg distutils-r1
+
+DESCRIPTION="Python bindings for GObject Introspection"
+HOMEPAGE="
+	https://pygobject.readthedocs.io/
+	https://gitlab.gnome.org/GNOME/pygobject/
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="+cairo examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.64:2
+	>=dev-libs/gobject-introspection-1.64:=
+	dev-libs/libffi:=
+	cairo? (
+		>=dev-python/pycairo-1.16.0[${PYTHON_USEDEP}]
+		x11-libs/cairo[glib]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		>=app-accessibility/at-spi2-core-2.46.0[introspection]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		x11-libs/gdk-pixbuf:2[introspection,jpeg]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection]
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+python_configure() {
+	local emesonargs=(
+		$(meson_feature cairo pycairo)
+		$(meson_use test tests)
+		-Dpython="${EPYTHON}"
+	)
+	meson_src_configure
+}
+
+python_compile() {
+	meson_src_compile
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x GIO_USE_VFS="local" # prevents odd issues with deleting ${T}/.gvfs
+	local -x GIO_USE_VOLUME_MONITOR="unix" # prevent udisks-related failures in chroots, bug #449484
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x XDG_CACHE_HOME="${T}/${EPYTHON}"
+	meson_src_test --timeout-multiplier 3 || die "test failed for ${EPYTHON}"
+}
+
+python_install() {
+	meson_src_install
+	python_optimize
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}
-- 
cgit v1.2.3-65-gdbad