From f13b25aeebb4fdf2a2f9ea15462f21341725629c Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Wed, 27 Jul 2022 22:09:46 +0200
Subject: dev-libs/libtar: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>
---
 dev-libs/libtar/libtar-1.2.20-r4.ebuild | 70 ---------------------------------
 dev-libs/libtar/libtar-1.2.20-r5.ebuild | 63 +++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+), 70 deletions(-)
 delete mode 100644 dev-libs/libtar/libtar-1.2.20-r4.ebuild
 create mode 100644 dev-libs/libtar/libtar-1.2.20-r5.ebuild

(limited to 'dev-libs/libtar')

diff --git a/dev-libs/libtar/libtar-1.2.20-r4.ebuild b/dev-libs/libtar/libtar-1.2.20-r4.ebuild
deleted file mode 100644
index 087a633aa6f4..000000000000
--- a/dev-libs/libtar/libtar-1.2.20-r4.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools
-
-DESCRIPTION="C library for manipulating tar archives"
-HOMEPAGE="https://repo.or.cz/w/libtar.git/"
-SRC_URI="https://dev.gentoo.org/~pinkbyte/distfiles/snapshots/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
-IUSE="static-libs zlib"
-
-RDEPEND="
-	zlib? ( sys-libs/zlib:= )
-	!zlib? ( app-arch/gzip )
-"
-DEPEND="${RDEPEND}"
-
-DOCS=( ChangeLog{,-1.0.x} README TODO )
-
-S="${WORKDIR}/${PN}"
-
-# There is no test and 'check' target errors out due to mixing of automake &
-# non-automake makefiles.
-# https://bugs.gentoo.org/show_bug.cgi?id=526436
-RESTRICT="test"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.2.11-free.patch
-	"${FILESDIR}"/${PN}-1.2.11-impl-dec.patch
-	"${FILESDIR}"/CVE-2013-4420.patch
-	"${FILESDIR}"/${P}-fd-leaks.patch
-	"${FILESDIR}"/${P}-tar_open-memleak.patch
-	"${FILESDIR}"/${P}-bin-memleaks.patch
-)
-
-src_prepare() {
-	default
-
-	sed -e '/INSTALL_PROGRAM/s:-s::' \
-		-i {doc,lib{,tar}}/Makefile.in || die
-
-	eautoreconf
-}
-
-src_configure() {
-	local myeconfargs=(
-		--enable-shared
-		--disable-encap
-		--disable-epkg-install
-		$(use_enable static-libs static)
-		$(use_with zlib)
-	)
-
-	econf ${myeconfargs[@]}
-}
-
-src_install() {
-	default
-
-	newdoc compat/README README.compat
-	newdoc compat/TODO TODO.compat
-	newdoc listhash/TODO TODO.listhash
-
-	find "${D}" -name '*.la' -delete || die
-}
diff --git a/dev-libs/libtar/libtar-1.2.20-r5.ebuild b/dev-libs/libtar/libtar-1.2.20-r5.ebuild
new file mode 100644
index 000000000000..c9c26bbb3adb
--- /dev/null
+++ b/dev-libs/libtar/libtar-1.2.20-r5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="C library for manipulating tar archives"
+HOMEPAGE="https://repo.or.cz/w/libtar.git/"
+SRC_URI="https://dev.gentoo.org/~pinkbyte/distfiles/snapshots/${P}.tar.gz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="zlib"
+# There is no test and 'check' target errors out due to mixing of automake &
+# non-automake makefiles.
+# https://bugs.gentoo.org/526436
+RESTRICT="test"
+
+RDEPEND="
+	zlib? ( sys-libs/zlib:= )
+	!zlib? ( app-arch/gzip )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.2.11-free.patch
+	"${FILESDIR}"/${PN}-1.2.11-impl-dec.patch
+	"${FILESDIR}"/CVE-2013-4420.patch
+	"${FILESDIR}"/${P}-fd-leaks.patch
+	"${FILESDIR}"/${P}-tar_open-memleak.patch
+	"${FILESDIR}"/${P}-bin-memleaks.patch
+)
+
+src_prepare() {
+	default
+
+	sed -e '/INSTALL_PROGRAM/s:-s::' \
+		-i {doc,lib{,tar}}/Makefile.in || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-encap
+		--disable-epkg-install
+		$(use_with zlib)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	dodoc ChangeLog-1.0.x
+	newdoc compat/README README.compat
+	newdoc compat/TODO TODO.compat
+	newdoc listhash/TODO TODO.listhash
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad