1 files changed, 43 insertions, 0 deletions
diff --git a/sys-libs/libvpd/libvpd-2.2.8.ebuild b/sys-libs/libvpd/libvpd-2.2.8.ebuild
new file mode 100644
index 000000000000..9c9a0165e233
--- /dev/null
+++ b/sys-libs/libvpd/libvpd-2.2.8.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools udev
+
+DESCRIPTION="Library implementation for listing Vital Product Data"
+HOMEPAGE="https://github.com/power-ras/libvpd"
+SRC_URI="https://github.com/power-ras/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~ppc ~ppc64"
+
+DEPEND="
+	dev-db/sqlite:3
+	sys-libs/zlib:=
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# sysconfdir is used only to establish where the udev rules file should go
+	# unfortunately it also adds the subdirs on its own so we strip it down to
+	# dirname
+	local myconf=(
+		--disable-static
+		--localstatedir="${EPREFIX}/var"
+		--sysconfdir="$( dirname $(get_udevdir) )"
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	keepdir /var/lib/lsvpd
+	find "${D}" -name '*.la' -delete || die
+}