1 files changed, 53 insertions, 0 deletions
diff --git a/dev-ml/re2/re2-113.24.00.ebuild b/dev-ml/re2/re2-113.24.00.ebuild
new file mode 100644
index 000000000000..13ddc93e5a15
--- /dev/null
+++ b/dev-ml/re2/re2-113.24.00.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+OASIS_BUILD_DOCS=1
+
+inherit oasis
+
+DESCRIPTION="OCaml bindings for RE2"
+HOMEPAGE="http://www.janestreet.com/ocaml"
+SRC_URI="http://ocaml.janestreet.com/ocaml-core/${PV%.*}/files/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND="
+	dev-ml/bin-prot:=
+	dev-ml/core_kernel:=
+	dev-ml/fieldslib:=
+	dev-ml/ppx_assert:=
+	dev-ml/ppx_bench:=
+	dev-ml/ppx_driver:=
+	dev-ml/ppx_expect:=
+	dev-ml/ppx_inline_test:=
+	dev-ml/ppx_jane:=
+	dev-ml/sexplib:=
+	dev-ml/typerep:=
+	dev-ml/variantslib:=
+"
+RDEPEND="${DEPEND}"
+DEPEND="${DEPEND} dev-ml/opam"
+
+src_configure() {
+	emake setup.exe
+	OASIS_SETUP_COMMAND="./setup.exe" oasis_src_configure
+}
+
+src_compile() {
+	emake
+}
+
+src_install() {
+	opam-installer -i \
+		--prefix="${ED}/usr" \
+		--libdir="${D}/$(ocamlc -where)" \
+		--docdir="${ED}/usr/share/doc/${PF}" \
+		${PN}.install || die
+	dodoc CHANGES.md
+}