net-wireless/iwd: bump to 0.16 & sync to live ebuild

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

3 files changed, 114 insertions, 1 deletions

diff --git a/net-wireless/iwd/Manifest b/net-wireless/iwd/Manifest
index ccccf166d1b2..c6960d218168 100644
--- a/net-wireless/iwd/Manifest
+++ b/net-wireless/iwd/Manifest
@@ -1 +1,2 @@
 DIST iwd-0.14.tar.xz 700844 BLAKE2B 69f3a1e5ead28cb602e7638e44d2a42a1b25831b837bf5f1d3436d3832a0548da7c3afe9f748688c194cf9e9bc5ea9303924ca1d36dea36d9e2233c245fc25eb SHA512 91713b3cbe8830abb95705e67c7b66f1ced368fe83eeaad36170da9df22b965e97485068e9342e09291aee669890de8f328e33fc3f092ba45097f523d83c7484
+DIST iwd-0.16.tar.xz 717880 BLAKE2B b4d1f3ebfc2f98920b205aefdf340cd55d803967a2b776e0798f1728cbd78e6be9b862f77b423ef2555b5f990341ef9b1e6f2aaf7460f08f37205a7edbaeda82 SHA512 33b10516fb203eb92651e18ebff8448874452fad9425470bf4306b4d75a512d386561ed4fcd251c54175ac6953e29f6574175e4e9b18c88e55009f670f29ddb1
diff --git a/net-wireless/iwd/iwd-0.16.ebuild b/net-wireless/iwd/iwd-0.16.ebuild
new file mode 100644
index 000000000000..93969ee59cb0
--- /dev/null
+++ b/net-wireless/iwd/iwd-0.16.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools flag-o-matic linux-info systemd
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/wireless/iwd.git"
+	inherit git-r3
+else
+	SRC_URI="https://www.kernel.org/pub/linux/network/wireless/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~x86"
+fi
+
+DESCRIPTION="Wireless daemon for linux"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/wireless/iwd.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+client +monitor ofono wired cpu_flags_x86_aes cpu_flags_x86_ssse3"
+
+RDEPEND="sys-apps/dbus
+	client? ( sys-libs/readline:0= )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+pkg_pretend() {
+	CONFIG_CHECK="
+		~ASYMMETRIC_KEY_TYPE
+		~ASYMMETRIC_PUBLIC_KEY_SUBTYPE
+		~CRYPTO_AES
+		~CRYPTO_ARC4
+		~CRYPTO_CBC
+		~CRYPTO_CMAC
+		~CRYPTO_DES
+		~CRYPTO_ECB
+		~CRYPTO_HMAC
+		~CRYPTO_MD4
+		~CRYPTO_MD5
+		~CRYPTO_RSA
+		~CRYPTO_SHA1
+		~CRYPTO_SHA256
+		~CRYPTO_SHA512
+		~CRYPTO_USER_API_HASH
+		~CRYPTO_USER_API_SKCIPHER
+		~KEY_DH_OPERATIONS
+		~PKCS7_MESSAGE_PARSER
+		~X509_CERTIFICATE_PARSER
+	"
+	if use amd64;then
+		CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_X86_64 ~CRYPTO_DES3_EDE_X86_64"
+		WARNING_CRYPTO_AES_X86_64="CRYPTO_AES_X86_64: enable for increased performance"
+		WARNING_CRYPTO_DES3_EDE_X86_64="CRYPTO_DES3_EDE_X86_64: enable for increased performance"
+	fi
+
+	if use cpu_flags_x86_aes;then
+		CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_AES_NI_INTEL"
+		WARNING_CRYPTO_AES_NI_INTEL="CRYPTO_AES_NI_INTEL: enable for increased performance"
+	fi
+
+	if use cpu_flags_x86_ssse3; then
+		CONFIG_CHECK="${CONFIG_CHECK} ~CRYPTO_SHA1_SSSE3 ~CRYPTO_SHA256_SSSE3 ~CRYPTO_SHA512_SSSE3"
+		WARNING_CRYPTO_SHA1_SSSE3="CRYPTO_SHA1_SSSE3: enable for increased performance"
+		WARNING_CRYPTO_SHA256_SSSE3="CRYPTO_SHA256_SSSE3: enable for increased performance"
+		WARNING_CRYPTO_SHA512_SSSE3="CRYPTO_SHA512_SSSE3: enable for increased performance"
+	fi
+
+	if use kernel_linux && kernel_is -ge 4 20; then
+		CONFIG_CHECK="${CONFIG_CHECK} ~PKCS8_PRIVATE_KEY_PARSER"
+	fi
+
+	check_extra_config
+}
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]] ; then
+		git-r3_src_unpack
+		git clone git://git.kernel.org/pub/scm/libs/ell/ell.git "${WORKDIR}"/ell
+	else
+		default
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	append-cflags "-fsigned-char"
+	econf --sysconfdir=/etc/iwd --localstatedir=/var \
+		$(use_enable client) \
+		$(use_enable monitor) \
+		$(use_enable ofono) \
+		$(use_enable wired) \
+		--enable-systemd-service \
+		--with-systemd-unitdir="$(systemd_get_systemunitdir)" \
+		--with-systemd-modloaddir=$(_systemd_get_dir modulesloaddir /usr/lib/modules-load.d)
+}
+
+src_install() {
+	default
+	keepdir /var/lib/${PN}
+
+	newinitd "${FILESDIR}/iwd.initd" iwd
+
+	if [[ ${PV} == "9999" ]] ; then
+		exeinto /usr/share/iwd/scripts/
+		doexe test/*
+	fi
+}
diff --git a/net-wireless/iwd/iwd-9999.ebuild b/net-wireless/iwd/iwd-9999.ebuild
index b037416528c5..93969ee59cb0 100644
--- a/net-wireless/iwd/iwd-9999.ebuild
+++ b/net-wireless/iwd/iwd-9999.ebuild
@@ -9,7 +9,7 @@ if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
 else
 	SRC_URI="https://www.kernel.org/pub/linux/network/wireless/${P}.tar.xz"
-	KEYWORDS="~amd64 ~x86"
+	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~x86"
 fi
 
 DESCRIPTION="Wireless daemon for linux"