games-engines/scrap-engine: New package at version 1.2.0

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

4 files changed, 72 insertions, 0 deletions

diff --git a/games-engines/scrap-engine/Manifest b/games-engines/scrap-engine/Manifest
new file mode 100644
index 000000000000..588b62dcbad7
--- /dev/null
+++ b/games-engines/scrap-engine/Manifest
@@ -0,0 +1 @@
+DIST scrap-engine-1.2.0.gh.tar.gz 381529 BLAKE2B a482bc45900a4294be69e22308114fcdaa4a8bcaa22bce96e3436080ca7dbd2a546253ed8d1faefe2fa5c2ec57a2c6b2a63cbd7b42de39d9990968f9b34614d7 SHA512 5d1ec65eed4515e07f3c3a32f0423bcf41d7ba594508391024d22623f27d052464b5a3dc887b0ff6bea6c8f7d7fe54c30373460449b9977f0f95a9e2b1f978da
diff --git a/games-engines/scrap-engine/files/scrap-engine-tests.patch b/games-engines/scrap-engine/files/scrap-engine-tests.patch
new file mode 100644
index 000000000000..5e7960574094
--- /dev/null
+++ b/games-engines/scrap-engine/files/scrap-engine-tests.patch
@@ -0,0 +1,12 @@
+diff -Naur a/tests/scrap_bench.py b/tests/scrap_bench.py
+--- a/tests/scrap_bench.py	2022-01-05 17:13:26.000000000 +0000
++++ b/tests/scrap_bench.py	2022-06-24 14:33:10.215047579 +0100
+@@ -22,7 +22,7 @@
+     time2 = 0
+
+     b_map.show()
+-    while True:
++    for _ in range(100):
+         time0 = time.time()
+         times += time2
+         for ob in rectangle.obs:
diff --git a/games-engines/scrap-engine/metadata.xml b/games-engines/scrap-engine/metadata.xml
new file mode 100644
index 000000000000..680b374c830b
--- /dev/null
+++ b/games-engines/scrap-engine/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">lxgr-linux/scrap_engine</remote-id>
+		<remote-id type="pypi">scrap-engine</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/games-engines/scrap-engine/scrap-engine-1.2.0.ebuild b/games-engines/scrap-engine/scrap-engine-1.2.0.ebuild
new file mode 100644
index 000000000000..05b7700f5b2a
--- /dev/null
+++ b/games-engines/scrap-engine/scrap-engine-1.2.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+MY_PN="${PN//-/_}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Terminal-based Python game engine involving objects on a map"
+HOMEPAGE="https://github.com/lxgr-linux/scrap_engine"
+SRC_URI="https://github.com/lxgr-linux/${MY_PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-tests.patch
+)
+
+DOCS=(
+	README.md
+	docs/DOCS.md
+	pics/example1.jpg
+)
+
+src_prepare() {
+	default
+
+	# PEP 517 needs this metadata.
+	echo "Version: ${PV}" > "${S}"/PKG-INFO || die
+
+	# Adjust doc resource paths.
+	sed -i "s:\.\./pics/::g" docs/DOCS.md || die
+}
+
+python_test() {
+	for TEST in "${S}"/tests/*.py; do
+		"${EPYTHON}" "${TEST}" || die
+	done
+}