dev-util/include-what-you-use: bump up to 0.15

clang-11 compatible release.

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

2 files changed, 59 insertions, 0 deletions

diff --git a/dev-util/include-what-you-use/Manifest b/dev-util/include-what-you-use/Manifest
index 8199d96737be..706b4c0b4297 100644
--- a/dev-util/include-what-you-use/Manifest
+++ b/dev-util/include-what-you-use/Manifest
@@ -1 +1,2 @@
 DIST include-what-you-use-10.0.tar.gz 598644 BLAKE2B 36c81bd493edfdfdc4df31c2dcb49d5acd3f6016f706e0c9d2f031d668ca16d71797d40b04fc9dc25a21738f7075320406fd666db74a0baa3832c149fe674e0e SHA512 e54a7c7e3a6d3e0de7c263d1f26b373d95b8fab5f1f7e76f52d80341bda2bad0fb12238a325dc1e2f6d3ab5e6d8e0b4ed60b5a19dc82e06d480bcb461f9aefba
+DIST include-what-you-use-11.0.tar.gz 603435 BLAKE2B 7bfa37349cc4bf5d07033c28d9d3851f0ce2093f1703a0392ac633ab2761dfdfb7cd923099177747e3389d2d41330351242c6f936399acf73119c201d8776978 SHA512 db15efa9b92015322e9a188be6cf16a5c6fd71271c94fde45245676f2a8f6ffe4c7837e3b0bb5f9be6cbe78aab245129816a3b046c44c261a2b7ab5c3a9ea7b9
diff --git a/dev-util/include-what-you-use/include-what-you-use-11.0.ebuild b/dev-util/include-what-you-use/include-what-you-use-11.0.ebuild
new file mode 100644
index 000000000000..662b79bec3f4
--- /dev/null
+++ b/dev-util/include-what-you-use/include-what-you-use-11.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit cmake flag-o-matic llvm python-single-r1
+
+# Sometimes the tag is clang_9, sometimes it's IWYU-0.13
+UPSTREAM_PV=0.15
+
+DESCRIPTION="Find unused include directives in C/C++ programs"
+HOMEPAGE="https://include-what-you-use.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${UPSTREAM_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+LLVM_MAX_SLOT=11
+
+RDEPEND="sys-devel/llvm:${LLVM_MAX_SLOT}
+	sys-devel/clang:${LLVM_MAX_SLOT}
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+S=${WORKDIR}/${PN}-${UPSTREAM_PV}
+
+pkg_setup() {
+	llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# Note [llvm install path]
+		# Unfortunately all binaries using clang driver
+		# have to reside at the same path depth as
+		# 'clang' binary itself. See bug #625972
+		# Thus as a hack we install it to the same directory
+		# as llvm/clang itself.
+		-DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix "${LLVM_MAX_SLOT}")"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${EPYTHON}" run_iwyu_tests.py
+}